Revision bump, change slot to 3.5, remove old

Package-Manager: portage-2.2_rc33/cvs/Linux x86_64

4 files changed, 180 insertions, 153 deletions

diff --git a/app-cdr/k3b/ChangeLog b/app-cdr/k3b/ChangeLog
index aa1d360b3a74..3d7c8f37c071 100644
--- a/app-cdr/k3b/ChangeLog
+++ b/app-cdr/k3b/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.218 2009/05/19 21:22:17 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.219 2009/05/24 16:41:00 tampakrap Exp $
+
+*k3b-1.0.5-r5 (24 May 2009)
+
+  24 May 2009; Theo Chatzimichos <tampakrap@gentoo.org>
+  -k3b-1.0.5-r3.ebuild, +k3b-1.0.5-r5.ebuild:
+  Revision bump, change slot to 3.5, remove old
 
   19 May 2009; Tomas Chvatal <scarabeus@gentoo.org> k3b-1.0.5-r4.ebuild:
   Fix error in dodoc. Per bug #270493.
diff --git a/app-cdr/k3b/Manifest b/app-cdr/k3b/Manifest
index 401c1e8c0e85..4caca2654bdc 100644
--- a/app-cdr/k3b/Manifest
+++ b/app-cdr/k3b/Manifest
@@ -1,10 +1,20 @@
+-----BEGIN PGP SIGNED MESSAGE-----
+Hash: SHA1
+
 AUX k3b-1.0.5-desktop-entry.diff 1756 RMD160 540b5336fde1206eba74ac25a4fd0276978ad9c6 SHA1 d817a1da34cc6207a1d5fcac0d5ba67a3964afc0 SHA256 3d89ee4194abe8312e7373161bac8b9134850906be9c6e738571f9de7adfb34b
 AUX k3b-1.0.5-ffmpeg-0.4.9_p20080326-API.patch 2991 RMD160 8d0204a12cfe1eabe03e66b6201e2164f01cd80d SHA1 6bab88b9e4619a7f61b82c6e59af9a7ef784f71b SHA256 e2db198914acbda0c33c20537449cf7b729345f9d8af0052701259de0b27ff21
 AUX k3b-1.0.5-ffmpeg-0.4.9_p20081014-API.patch 1049 RMD160 022fecbc707775adc782b828bfdd571eccb95936 SHA1 270f19b05ce7ca35aee0dd7009556fec9b66f90c SHA256 e99f6b309e6c20d085860c495c2aa9d34d6d69a864e0be11aac01e0b3a6ac67d
 AUX k3b-1.0.5-transcode-1.1.patch 1097 RMD160 08fcc3769803a400bc5d00be223b9f37fdc7e7d0 SHA1 68547f4e312dc30c6440bed126a4408716b78e13 SHA256 8317afcf5e26dd5195065f2eb3b062e41804c46afe9d3c906012dee6249290f4
 DIST k3b-1.0.5.tar.bz2 5113060 RMD160 b562746015cc2e4226652402725b4e69eb846822 SHA1 c45d6f2a36b1bc7ea14101d444149c40fd4b700e SHA256 d4f9799f234ade98b7e417d1493de3bd4a44fd937e813c2beb29eba02cda50df
 DIST k3b-i18n-1.0.5.tar.bz2 7732137 RMD160 6f08c6851da5d25ed4b2ead4ad0c4073ba94e246 SHA1 8697c0f0a9fa458895519a5d94c50120333a71c8 SHA256 068b170cd63c97263d21165b7b5106a8176f2499a1ebcec9baa68b7628395767
-EBUILD k3b-1.0.5-r3.ebuild 4444 RMD160 58125b716f9cf46d0e36c5347d7012e2037bf794 SHA1 d14adb1440085fa783108de6f46353fb9627f824 SHA256 22edb0f79e17453f47e821a6d903739a6169e1ce2b07e054d80a732e7399adb6
 EBUILD k3b-1.0.5-r4.ebuild 3870 RMD160 7e99616ef288524e525f8d91edc9299edc26819d SHA1 d3b4e138640be80a6185403657262de3a6bf2102 SHA256 2585b9e0cfb1fc184052c57a0cc2de3ea7cd6c5057e64744d372939d7e6d2b87
-MISC ChangeLog 32020 RMD160 09c6dc42dfa271d063152b7a90bf3f8546ec1d45 SHA1 8e7644a63b7806e83d5c242a63fc1c7522d04ec1 SHA256 747d2609025ad34072d315d99f8b34c7bcb95fcba29436227d21f97bbda2e880
+EBUILD k3b-1.0.5-r5.ebuild 3902 RMD160 2f0ac77553c86a8cf81735e7dc975526c22bf4dc SHA1 8c515b14a80773a56afc1defb600f893a878c35a SHA256 c48a8bf7c5416ea92ccb397ba3b6da015381c8a46162da76852ebdf826279205
+MISC ChangeLog 32200 RMD160 72f2dd5bac20a97c33941928be9f4196f21ed8d9 SHA1 2a5a7620aeff1cb4f9e8dfb7ab0bbdb5dd6ba7d6 SHA256 361574e92888089c0453836c9b8285b8c2dc3daf3850cdda800c0008450d39ca
 MISC metadata.xml 265 RMD160 59c880c9c5efb9521978dbd903168505b105564a SHA1 c7ff34e4da0ae454589f8ae79f0c074915754879 SHA256 017dbf66cb3b0c2b77f42714c7544570e19f9605bb260245094b3678a6a34324
+-----BEGIN PGP SIGNATURE-----
+Version: GnuPG v2.0.11 (GNU/Linux)
+
+iEYEARECAAYFAkoZezAACgkQjDdoMVfcAHjtKwCbBjd1GVi5VNzlCZToF6Bi3zYS
+P1MAn1FdBIBYKFv2WGYPpjKA4BvK5AF/
+=G+Ln
+-----END PGP SIGNATURE-----
diff --git a/app-cdr/k3b/k3b-1.0.5-r3.ebuild b/app-cdr/k3b/k3b-1.0.5-r3.ebuild
deleted file mode 100644
index 77264588ccec..000000000000
--- a/app-cdr/k3b/k3b-1.0.5-r3.ebuild
+++ /dev/null
@@ -1,150 +0,0 @@
-# Copyright 1999-2009 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.0.5-r3.ebuild,v 1.7 2009/03/10 20:02:18 beandog Exp $
-
-inherit kde eutils
-
-MY_P=${P/_/}
-S="${WORKDIR}/${MY_P}"
-
-DESCRIPTION="K3b, KDE CD Writing Software"
-HOMEPAGE="http://www.k3b.org/"
-SRC_URI="mirror://sourceforge/k3b/${MY_P}.tar.bz2"
-LICENSE="GPL-2"
-
-SLOT="0"
-KEYWORDS="amd64 ppc ppc64 x86 ~x86-fbsd"
-IUSE="alsa css dvd dvdr encode ffmpeg flac hal mp3 musepack musicbrainz
-	sndfile vcd vorbis emovix"
-
-DEPEND="hal? ( dev-libs/dbus-qt3-old sys-apps/hal )
-	media-libs/libsamplerate
-	media-libs/taglib
-	>=media-sound/cdparanoia-3.9.8
-	sndfile? ( media-libs/libsndfile )
-	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20080326 )
-	flac? ( media-libs/flac )
-	mp3? ( media-libs/libmad )
-	musepack? ( media-libs/libmpcdec )
-	vorbis? ( media-libs/libvorbis )
-	musicbrainz? ( =media-libs/musicbrainz-2* )
-	encode? ( media-sound/lame )
-	alsa? ( media-libs/alsa-lib )
-	dvd? ( media-libs/libdvdread )"
-
-RDEPEND="${DEPEND}
-	virtual/cdrtools
-	>=app-cdr/cdrdao-1.1.7-r3
-	media-sound/normalize
-	dvdr? ( >=app-cdr/dvd+rw-tools-7.0 )
-	css? ( media-libs/libdvdcss )
-	encode? ( media-sound/sox
-				media-video/transcode )
-	vcd? ( media-video/vcdimager )
-	emovix? ( media-video/emovix )"
-
-DEPEND="${DEPEND}
-	dev-util/pkgconfig"
-
-need-kde 3.5
-
-PATCHES=(	"${FILESDIR}/k3b-1.0.5-desktop-entry.diff"
-		"${FILESDIR}/k3b-1.0.5-ffmpeg-0.4.9_p20080326-API.patch"
-		"${FILESDIR}/k3b-1.0.5-ffmpeg-0.4.9_p20081014-API.patch"	)
-
-I18N="${PN}-i18n-${PV}"
-
-# Supported languages and translated documentation
-LANGS="af ar bg br bs ca cs cy da de el en_GB es et eu fa fi fr ga gl he hi hu is it ja ka lt mk ms nb nds nl nn pa pl pt pt_BR ru rw se sk sr sr@Latn sv ta tr uk uz zh_CN zh_TW"
-for X in ${LANGS}; do
-	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
-	IUSE="${IUSE} linguas_${X}"
-done
-
-pkg_setup() {
-	if use hal && has_version '<sys-apps/dbus-0.91' && ! built_with_use sys-apps/dbus qt3; then
-		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"hal\" USE flag enabled,"
-		eerror "but sys-apps/dbus is not built with Qt3 support."
-		die "Please, rebuild sys-apps/dbus with the \"qt3\" USE flag."
-	fi
-	if use encode && ! built_with_use media-video/transcode dvd; then
-		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"encode\""
-		eerror "USE flag enabled, however media-video/transcode was not built"
-		eerror "with libdvdread support. Also keep in mind that enabling"
-		eerror "the dvd USE flag will cause k3b to use libdvdread as well."
-		die "Please, rebuild media-video/transcode with the \"dvd\" USE flag."
-	fi
-
-	if use flac && ! built_with_use --missing true media-libs/flac cxx; then
-		eerror "To build ${PN} with flac support you need the C++ bindings for flac."
-		eerror "Please enable the cxx USE flag for media-libs/flac"
-		die "Missing FLAC C++ bindings."
-	fi
-
-	kde_pkg_setup
-}
-
-src_unpack() {
-	kde_src_unpack
-
-	if [ -d "${WORKDIR}/${I18N}" ]; then
-		cd "${WORKDIR}/${I18N}"
-		for X in ${LANGS}; do
-			use linguas_${X} || rm -rf "${X}"
-		done
-		rm -f configure
-	fi
-	rm -f "${S}/configure"
-}
-
-src_compile() {
-	local myconf="--enable-libsuffix=		\
-			--with-external-libsamplerate	\
-			--without-resmgr				\
-			--without-cdrecord-suid-root	\
-			--without-k3bsetup				\
-			$(use_with hal)					\
-			$(use_with encode lame)			\
-			$(use_with ffmpeg)				\
-			$(use_with flac)				\
-			$(use_with vorbis oggvorbis)	\
-			$(use_with sndfile)				\
-			$(use_with mp3 libmad)			\
-			$(use_with musepack)			\
-			$(use_with musicbrainz)			\
-			$(use_with dvd libdvdread)	\
-			$(use_with alsa)"
-
-	# Build process of K3b
-	kde_src_compile
-
-	# Build process of K3b-i18n
-	if [ -d "${WORKDIR}/${I18N}" ]; then
-		KDE_S="${WORKDIR}/${I18N}" \
-		kde_src_compile
-	fi
-}
-
-src_install() {
-	kde_src_install
-	dodoc FAQ KNOWNBUGS PERMISSIONS
-
-	if [ -d "${WORKDIR}/${I18N}" ]; then
-		KDE_S="${WORKDIR}/${I18N}" \
-		kde_src_install
-	fi
-}
-
-pkg_postinst() {
-	echo
-	elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
-	elog "If you get warnings on start-up, uncheck the \"Check system"
-	elog "configuration\" option in the \"Misc\" settings window."
-	echo
-
-	local group=cdrom
-	use kernel_linux || group=operator
-	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
-	elog "Usually, it is sufficient to be in the ${group} group."
-	echo
-}
diff --git a/app-cdr/k3b/k3b-1.0.5-r5.ebuild b/app-cdr/k3b/k3b-1.0.5-r5.ebuild
new file mode 100644
index 000000000000..46326e6c4392
--- /dev/null
+++ b/app-cdr/k3b/k3b-1.0.5-r5.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.0.5-r5.ebuild,v 1.1 2009/05/24 16:41:00 tampakrap Exp $
+
+EAPI="2"
+
+inherit kde eutils multilib
+
+MY_P="${P/_/}"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="K3b, KDE CD Writing Software"
+HOMEPAGE="http://www.k3b.org/"
+SRC_URI="mirror://sourceforge/k3b/${MY_P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="3.5"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="alsa css dvd dvdr encode emovix ffmpeg flac hal mp3 musepack musicbrainz
+	sndfile vcd vorbis"
+
+COMMON_DEPEND="
+	!<app-cdr/k3b-1.0.5-r5
+	media-libs/libsamplerate
+	media-libs/taglib
+	>=media-sound/cdparanoia-3.9.8
+	alsa? ( media-libs/alsa-lib )
+	dvd? ( media-libs/libdvdread )
+	encode? ( media-sound/lame )
+	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20080326 )
+	flac? ( media-libs/flac[cxx] )
+	hal? ( sys-apps/hal )
+	mp3? ( media-libs/libmad )
+	musepack? ( media-libs/libmpcdec )
+	musicbrainz? ( media-libs/musicbrainz:1 )
+	sndfile? ( media-libs/libsndfile )
+	vorbis? ( media-libs/libvorbis )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=app-cdr/cdrdao-1.1.7-r3
+	media-sound/normalize
+	virtual/cdrtools
+	dvdr? ( >=app-cdr/dvd+rw-tools-7.0 )
+	css? ( media-libs/libdvdcss )
+	encode? (
+		media-sound/sox
+		media-video/transcode[dvd]
+	)
+	emovix? ( media-video/emovix )
+	vcd? ( media-video/vcdimager )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-util/pkgconfig"
+
+need-kde 3.5
+
+PATCHES=(
+	"${FILESDIR}/${P}-desktop-entry.diff"
+	"${FILESDIR}/${P}-ffmpeg-0.4.9_p20080326-API.patch"
+	"${FILESDIR}/${P}-ffmpeg-0.4.9_p20081014-API.patch"
+	"${FILESDIR}/${P}-transcode-1.1.patch"
+)
+
+I18N="${PN}-i18n-${PV}"
+
+# Supported languages and translated documentation
+LANGS="af ar bg br bs ca cs cy da de el en_GB es et eu fa fi fr ga gl he hi hu is it
+	ja ka lt mk ms nb nds nl nn pa pl pt pt_BR ru rw se sk sr sr@Latn sv ta tr uk
+	uz zh_CN zh_TW"
+for X in ${LANGS}; do
+	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
+	IUSE="${IUSE} linguas_${X}"
+done
+
+src_unpack() {
+	kde_src_unpack
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		cd "${WORKDIR}/${I18N}"
+		for X in ${LANGS}; do
+			use linguas_${X} || rm -rf "${X}"
+		done
+		rm -f configure
+	fi
+	rm -f "${S}/configure"
+}
+
+src_configure() {
+	local myconf="--with-external-libsamplerate
+		--without-resmgr
+		--without-cdrecord-suid-root
+		--without-k3bsetup
+		--with-qt-dir=${QTDIR}
+		--enable-mt
+		--with-qt-libraries=${QTDIR}/$(get_libdir)
+		--disable-dependency-tracking
+		--without-arts
+		$(use_enable debug)
+		$(use_with hal)
+		$(use_with encode lame)
+		$(use_with ffmpeg)
+		$(use_with flac)
+		$(use_with vorbis oggvorbis)
+		$(use_with sndfile)
+		$(use_with mp3 libmad)
+		$(use_with musepack)
+		$(use_with musicbrainz)
+		$(use_with dvd libdvdread)
+		$(use_with alsa)"
+
+	# Build process of K3b
+	kde_src_configure
+
+	# Build process of K3b-i18n
+	if [[ -d "${WORKDIR}/${I18N}" ]]; then
+		myconf="--with-qt-dir=${QTDIR}
+			--with-qt-libraries=${QTDIR}/$(get_libdir)
+			--disable-dependency-tracking
+			--without-arts
+			$(use_enable debug)"
+
+		KDE_S="${WORKDIR}/${I18N}"
+		kde_src_configure
+	fi
+}
+
+src_compile() {
+	KDE_S="${S}"
+	kde_src_compile
+
+	if [[ -d "${WORKDIR}/${I18N}" ]]; then
+		KDE_S="${WORKDIR}/${I18N}"
+		kde_src_compile
+	fi
+}
+
+src_install() {
+	KDE_S="${S}"
+	kde_src_install
+	dodoc FAQ KNOWNBUGS PERMISSIONS || die "dodoc failed"
+
+	if [[ -d "${WORKDIR}/${I18N}" ]]; then
+		KDE_S="${WORKDIR}/${I18N}"
+		kde_src_install
+	fi
+}
+
+pkg_postinst() {
+	echo
+	elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}