blob: d1fdc3096fce486be3e69df25db0a03206bfde92 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit java-pkg-opt-2 python-r1 toolchain-funcs
DESCRIPTION="Library for Support Vector Machines"
HOMEPAGE="https://www.csie.ntu.edu.tw/~cjlin/libsvm/"
SRC_URI="https://www.csie.ntu.edu.tw/~cjlin/libsvm/${PN}-${PV/0}.tar.gz"
S="${WORKDIR}/${PN}-${PV/0}"
LICENSE="BSD"
SLOT="0/2"
KEYWORDS="amd64 ~ppc ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="java openmp python tools"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
DEPEND="
java? ( >=virtual/jdk-1.8:* )
python? ( ${PYTHON_DEPS} )
"
RDEPEND="
java? ( >=virtual/jre-1.8:* )
python? ( ${PYTHON_DEPS} )
tools? ( sci-visualization/gnuplot )
"
PATCHES=(
"${FILESDIR}"/${PN}-3.25-openmp.patch
"${FILESDIR}"/${PN}-3.30-makefile.patch
"${FILESDIR}"/${PN}-3.30-javaMakefile.patch
)
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
src_prepare() {
default
java-pkg_clean
sed -i -e "s@\.\./@${EPREFIX}/usr/bin/@g" tools/*.py \
|| die "Failed to fix paths in python files"
sed -i -e "s|./grid.py|${EPREFIX}/usr/bin/svm-grid|g" tools/*.py \
|| die "Failed to fix paths for svm-grid"
sed -i -e 's/grid.py/svm-grid/g' tools/grid.py \
|| die "Failed to rename grid.py to svm-grid"
}
src_configure() {
use java && export JAVAC_FLAGS="$(java-pkg_javac-args)"
if use openmp; then
export OPENMP_CFLAGS="-fopenmp -DOPENMP"
export OPENMP_LIBS="-fopenmp"
fi
tc-export CXX CC
}
src_compile() {
default
use java && emake -C java
}
src_install() {
dobin svm-train svm-predict svm-scale
dolib.so *.so*
doheader svm.h
DOCS=( README )
if use tools; then
local t
for t in tools/*.py; do
python_foreach_impl python_newscript ${t} svm-$(basename ${t} .py)
done
mv tools/README{,.tools} || die
DOCS+=( tools/README.tools )
docinto examples
dodoc heart_scale
dodoc -r svm-toy
docompress -x /usr/share/doc/${PF}/examples
fi
if use python ; then
installation() {
touch python/__init__.py || die
python_moduleinto libsvm
python_domodule python/*.py
}
python_foreach_impl installation
mv python/README{,.python} || die
DOCS+=( python/README.python )
fi
HTML_DOCS=( FAQ.html )
if use java; then
java-pkg_dojar java/libsvm.jar
HTML_DOCS+=( java/test_applet.html )
fi
einstalldocs
}
|
GitWeb