blob: 68144574adea58c8325098be48e55b9c2b40f3d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools git-r3
DESCRIPTION="A library and tools for trace processing"
HOMEPAGE="https://research.wand.net.nz/software/libtrace.php"
EGIT_REPO_URI="https://github.com/LibtraceTeam/libtrace"
EGIT_SUBMODULES=()
LICENSE="LGPL-3"
SLOT="0"
KEYWORDS=""
IUSE="doc ncurses numa static-libs"
RDEPEND="
>=net-libs/libpcap-0.8
dev-libs/libyaml
dev-libs/openssl:0=
net-libs/wandio
ncurses? ( sys-libs/ncurses:0= )
numa? ( sys-process/numactl )
"
DEPEND="
${RDEPEND}
app-doc/doxygen[dot]
sys-devel/flex
virtual/os-headers
virtual/pkgconfig
virtual/yacc
"
PATCHES=(
"${FILESDIR}"/${PN}-3.0.20-autoconf-1.13.patch
"${FILESDIR}"/${PN}-4.0.0-no-examples.patch
"${FILESDIR}"/${PN}-4.0.0-with-numa.patch
"${FILESDIR}"/${PN}-4.0.9_p1-tinfo.patch
)
S=${WORKDIR}/${P/_beta/}
src_prepare() {
default
eautoreconf
# Comment out FILE_PATTERNS definition (bug #706230)
if has_version ~app-doc/doxygen-1.8.16; then
sed -i -e '/^FILE_PATTERNS/s|^|#|g' docs/${PN}.doxygen.in || die
fi
# Update doxygen configuration
doxygen -u docs/libtrace.doxygen.in || die
}
src_configure() {
econf \
$(use_enable static-libs static) \
$(use_with ncurses) \
$(use_with numa) \
--with-man
}
src_install() {
default
use doc && dodoc -r docs/doxygen/html
find "${D}" -name "*.la" -delete || die
}
|
GitWeb
