blob: f54b981fe3da5d5ec945b23ec248a65ffd9ef368 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
DISTUTILS_USE_SETUPTOOLS=no
inherit desktop distutils-r1 optfeature xdg-utils
if [[ ${PV} != *9999* ]]; then
KEYWORDS="~amd64 ~arm64 ~x86"
SRC_URI="https://foss.heptapod.net/mercurial/${PN}/thg/-/archive/${PV}/thg-${PV}.tar.gz -> ${P}.tar.gz"
HG_DEPEND=">=dev-vcs/mercurial-5.7[${PYTHON_USEDEP}]
<dev-vcs/mercurial-5.9[${PYTHON_USEDEP}]"
S="${WORKDIR}/thg-${PV}"
else
inherit mercurial
EHG_REPO_URI="https://foss.heptapod.net/mercurial/${PN}/thg"
EHG_REVISION="stable"
HG_DEPEND=">=dev-vcs/mercurial-5.7[${PYTHON_USEDEP}]"
fi
DESCRIPTION="Set of graphical tools for Mercurial"
HOMEPAGE="https://tortoisehg.bitbucket.io/"
LICENSE="GPL-2"
SLOT="0"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
${HG_DEPEND}
dev-python/iniparse[${PYTHON_USEDEP}]
dev-python/pygments[${PYTHON_USEDEP}]
dev-python/PyQt5[network,svg,${PYTHON_USEDEP}]
>=dev-python/qscintilla-python-2.9.4[qt5(+),${PYTHON_USEDEP}]
"
DEPEND="
${RDEPEND}
test? (
dev-python/mock
dev-python/pytest
)
"
distutils_enable_sphinx doc/source
python_prepare_all() {
# Remove file that collides with >=mercurial-4.0 (bug #599266).
rm "${S}"/hgext3rd/__init__.py || die "can't remove /hgext3rd/__init__.py"
sed -i -e 's:share/doc/tortoisehg:share/doc/'"${PF}"':' setup.py || die
distutils-r1_python_prepare_all
}
python_test() {
${EPYTHON} tests/run-tests.py -m 'not largefiles' --doctest-modules tests || die
${EPYTHON} tests/run-tests.py -m largefiles tests || die
}
python_install_all() {
distutils-r1_python_install_all
dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
domenu contrib/thg.desktop
}
pkg_postinst() {
xdg_icon_cache_update
elog "When startup of ${PN} fails with an API version mismatch error"
elog "between dev-python/sip and dev-python/PyQt5 please rebuild"
elog "dev-python/qscintilla-python."
optfeature "the core git extension support" dev-python/pygit2
}
pkg_postrm() {
xdg_icon_cache_update
}
|
GitWeb