blob: 93e03c1a2bbd8edef997061a810747fe30ac3622 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Copyright 2023-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit llvm meson python-any-r1
MY_PV="${PV/_/-}"
DESCRIPTION="intel_clc tool used for building OpenCL C to SPIR-V"
HOMEPAGE="https://mesa3d.org/"
if [[ ${PV} == 9999 ]]; then
S="${WORKDIR}/intel_clc-${MY_PV}"
EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git"
inherit git-r3
else
S="${WORKDIR}/mesa-${MY_PV}"
SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz"
KEYWORDS="amd64"
fi
LICENSE="MIT SGI-B-2.0"
SLOT="0"
IUSE="debug"
RDEPEND="
dev-libs/libclc
dev-util/spirv-tools
>=sys-libs/zlib-1.2.8:=
x11-libs/libdrm
"
DEPEND="${RDEPEND}
dev-libs/expat
"
BDEPEND="
${PYTHON_DEPS}
$(python_gen_any_dep ">=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]")
virtual/pkgconfig
"
# Please keep the LLVM dependency block separate. Since LLVM is slotted,
# we need to *really* make sure we're not pulling one than more slot
# simultaneously.
#
# How to use it:
# 1. Specify LLVM_MAX_SLOT (inclusive), e.g. 17.
# 2. Specify LLVM_MIN_SLOT (inclusive), e.g. 15.
LLVM_MAX_SLOT="17"
LLVM_MIN_SLOT="15"
PER_SLOT_DEPSTR="
(
dev-util/spirv-llvm-translator:@SLOT@
sys-devel/clang:@SLOT@
sys-devel/llvm:@SLOT@
)
"
LLVM_DEPSTR="
|| (
$(for ((slot=LLVM_MAX_SLOT; slot>=LLVM_MIN_SLOT; slot--)); do
echo "${PER_SLOT_DEPSTR//@SLOT@/${slot}}"
done)
)
<sys-devel/clang-$((LLVM_MAX_SLOT + 1)):=
<sys-devel/llvm-$((LLVM_MAX_SLOT + 1)):=
"
RDEPEND="${RDEPEND}
${LLVM_DEPSTR}
"
unset LLVM_MIN_SLOT {LLVM,PER_SLOT}_DEPSTR
llvm_check_deps() {
has_version "dev-util/spirv-llvm-translator:${LLVM_SLOT}" &&
has_version "sys-devel/clang:${LLVM_SLOT}" &&
has_version "sys-devel/llvm:${LLVM_SLOT}"
}
python_check_deps() {
python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]"
}
pkg_setup() {
llvm_pkg_setup
python-any-r1_pkg_setup
}
src_configure() {
PKG_CONFIG_PATH="$(get_llvm_prefix "${LLVM_MAX_SLOT}")/$(get_libdir)/pkgconfig"
local emesonargs=(
-Dllvm=enabled
-Dshared-llvm=enabled
-Dintel-clc=enabled
-Dgallium-drivers=''
-Dvulkan-drivers=''
# Set platforms empty to avoid the default "auto" setting. If
# platforms is empty meson.build will add surfaceless.
-Dplatforms=''
-Dglx=disabled
-Dlibunwind=disabled
-Dzstd=disabled
-Dbuildtype=$(usex debug debug plain)
-Db_ndebug=$(usex debug false true)
)
meson_src_configure
}
src_install() {
dobin "${BUILD_DIR}"/src/intel/compiler/intel_clc
}
|
GitWeb