blob: 862606756cbf9a5d8a4e2b80a0bc0c1a2c6fb040 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils multilib
# test phase only works if ecls already installed #516876
RESTRICT="test"
MY_P=ecl-${PV}
DESCRIPTION="ECL is an embeddable Common Lisp implementation"
HOMEPAGE="https://common-lisp.net/project/ecl/"
SRC_URI="https://common-lisp.net/project/ecl/static/files/release/${MY_P}.tgz"
LICENSE="BSD-2 LGPL-2.1+"
SLOT="0/${PV}"
KEYWORDS="amd64 ~ppc ~sparc x86"
IUSE="cxx debug emacs gengc precisegc cpu_flags_x86_sse +threads +unicode +libatomic X"
CDEPEND="dev-libs/gmp:0
virtual/libffi
libatomic? ( dev-libs/libatomic_ops )
>=dev-libs/boehm-gc-7.1[threads?]
>=dev-lisp/asdf-2.33-r3:="
DEPEND="${CDEPEND}
app-text/texi2html
emacs? ( >=app-editors/emacs-23.1:* >=app-eselect/eselect-emacs-1.12 )"
RDEPEND="${CDEPEND}"
S="${WORKDIR}"/${MY_P}
PATCHES=(
"${FILESDIR}/${P}-headers-gentoo.patch"
"${FILESDIR}/${P}-build.patch"
)
pkg_setup () {
if use gengc || use precisegc ; then
ewarn "You have enabled the generational garbage collector or"
ewarn "the precise collection routines. These features are not very stable"
ewarn "at the moment and may cause crashes."
ewarn "Don't enable them unless you know what you're doing."
fi
}
src_prepare() {
default
cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
}
src_configure() {
econf \
--with-system-gmp \
--enable-boehm=system \
--enable-longdouble=yes \
--with-dffi \
$(use_with cxx) \
$(use_enable gengc) \
$(use_enable precisegc) \
$(use_with debug debug-cflags) \
$(use_enable libatomic libatomic system) \
$(use_with cpu_flags_x86_sse sse) \
$(use_enable threads) \
$(use_with threads __thread) \
$(use_enable unicode) \
$(use_with unicode unicode-names) \
$(use_with X x)
}
src_compile() {
if use emacs; then
local ETAGS=$(eselect --brief etags list | sed -ne '/emacs/{p;q}')
[[ -n ${ETAGS} ]] || die "No etags implementation found"
pushd build > /dev/null || die
emake ETAGS=${ETAGS} TAGS
popd > /dev/null
else
touch build/TAGS
fi
#parallel make fails
emake -j1
}
src_install () {
emake DESTDIR="${D}" install
dodoc README.md CHANGELOG
dodoc "${FILESDIR}"/README.Gentoo
pushd build/doc
newman ecl.man ecl.1
newman ecl-config.man ecl-config.1
popd
}
|
GitWeb