dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ADA_COMPAT=( gnat_2021 gcc_12_2_0 gcc_12 )
inherit ada multiprocessing

DESCRIPTION="GPR Unit Provider"
HOMEPAGE="https://github.com/AdaCore/gpr-unit-provider"
SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
	-> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"

RDEPEND="${ADA_DEPS}
	dev-ada/gpr[${ADA_USEDEP},shared?]
	dev-ada/libadalang[${ADA_USEDEP},static-libs]
	shared? ( dev-ada/libadalang[static-pic] )"
DEPEND="${RDEPEND}"
BDEPEND=""

IUSE="+shared"
REQUIRED_USE="${ADA_REQUIRED_USE}"

src_compile() {
	emake PROCESSORS=$(makeopts_jobs) \
		ENABLE_SHARED=$(usex shared) \
		GPRBUILD_OPTIONS=-v
}

src_install() {
	emake ENABLE_SHARED=$(usex shared) \
		prefix="${D}"/usr \
		install
	einstalldocs
}