1 files changed, 62 insertions, 0 deletions
diff --git a/x11-misc/x11vnc/x11vnc-0.9.14.ebuild b/x11-misc/x11vnc/x11vnc-0.9.14.ebuild
new file mode 100644
index 000000000000..082943171578
--- /dev/null
+++ b/x11-misc/x11vnc/x11vnc-0.9.14.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools eutils vcs-snapshot
+
+DESCRIPTION="A VNC server for real X displays"
+HOMEPAGE="https://libvnc.github.io/"
+SRC_URI="https://github.com/LibVNC/x11vnc/archive/0.9.14.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="avahi crypt fbcon libressl ssl xinerama"
+
+RDEPEND=">=net-libs/libvncserver-0.9.8
+	x11-libs/libX11
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	>=x11-libs/libXtst-1.1.0
+	avahi? ( >=net-dns/avahi-0.6.4 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+	xinerama? ( x11-libs/libXinerama )"
+DEPEND="${RDEPEND}
+	x11-libs/libXt
+	x11-proto/inputproto
+	x11-proto/trapproto
+	x11-proto/recordproto
+	x11-proto/xproto
+	x11-proto/xextproto
+	xinerama? ( x11-proto/xineramaproto )"
+
+DOCS=(ChangeLog README)
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	# --without-v4l because of missing video4linux 2.x support wrt #389079
+	econf \
+		$(use_with avahi) \
+		$(use_with crypt) \
+		$(use_with fbcon fbdev) \
+		$(use_with ssl) \
+		$(use_with ssl crypto) \
+		--without-v4l \
+		$(use_with xinerama)
+}
+
+src_install() {
+	default
+	doinitd "${FILESDIR}/x11vnc.init.d"
+	doconfd "${FILESDIR}/x11vnc.conf.d"
+}