1 files changed, 50 insertions, 0 deletions
diff --git a/media-libs/libXcm/libXcm-0.5.4.ebuild b/media-libs/libXcm/libXcm-0.5.4.ebuild
new file mode 100644
index 000000000000..5d7c28e002d8
--- /dev/null
+++ b/media-libs/libXcm/libXcm-0.5.4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+if [[ ${PV} = *9999 ]]; then
+	GITECLASS="git-r3"
+	EGIT_REPO_URI="https://github.com/oyranos-cms/libxcm.git"
+fi
+inherit autotools multilib-minimal ${GITECLASS}
+unset GITECLASS
+
+DESCRIPTION="Reference implementation of the X Color Management specification"
+HOMEPAGE="http://www.oyranos.org/libxcm/"
+[[ ${PV} != *9999 ]] && \
+SRC_URI="https://github.com/oyranos-cms/${PN,,}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="static-libs X"
+
+RDEPEND="
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXfixes[${MULTILIB_USEDEP}]
+		x11-libs/libXmu[${MULTILIB_USEDEP}]
+		x11-proto/xproto[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+
+[[ ${PV} != *9999 ]] && S="${WORKDIR}/${P,,}"
+
+src_prepare() {
+	default
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with X x11)
+}
+
+multilib_src_install_all() {
+	find "${D}" -name '*.la' -delete || die
+}