1 files changed, 51 insertions, 0 deletions
diff --git a/dev-python/django-haystack/django-haystack-2.4.1.ebuild b/dev-python/django-haystack/django-haystack-2.4.1.ebuild
new file mode 100644
index 000000000000..df67e6d8d5cc
--- /dev/null
+++ b/dev-python/django-haystack/django-haystack-2.4.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Pluggable search for Django"
+HOMEPAGE="http://haystacksearch.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/django-1.6[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/elasticsearch-py[$(python_gen_usedep 'python*')]
+		dev-python/geopy[$(python_gen_usedep 'python*')]
+		dev-python/lxml[$(python_gen_usedep 'python*')]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/pysolr-3.2.0[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/whoosh[${PYTHON_USEDEP}]
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	"
+
+RESTRICT="test"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	${EPYTHON} test_haystack/solr_tests/server/wait-for-solr
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}