1 files changed, 63 insertions, 0 deletions
diff --git a/dev-libs/libressl/libressl-3.1.2.ebuild b/dev-libs/libressl/libressl-3.1.2.ebuild
new file mode 100644
index 000000000000..ab31f2041689
--- /dev/null
+++ b/dev-libs/libressl/libressl-3.1.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal libtool
+
+DESCRIPTION="Free version of the SSL/TLS protocol forked from OpenSSL"
+HOMEPAGE="https://www.libressl.org/"
+SRC_URI="https://ftp.openbsd.org/pub/OpenBSD/LibreSSL/${P}.tar.gz"
+
+LICENSE="ISC openssl"
+# Reflects ABI of libcrypto.so and libssl.so. Since these can differ,
+# we'll try to use the max of either. However, if either change between
+# versions, we have to change the subslot to trigger rebuild of consumers.
+SLOT="0/48"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+asm static-libs test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="test? ( static-libs )"
+
+RDEPEND="!dev-libs/openssl:0"
+DEPEND="${RDEPEND}"
+PDEPEND="app-misc/ca-certificates"
+
+src_prepare() {
+	touch crypto/Makefile.in
+
+	sed -i \
+		-e '/^[ \t]*CFLAGS=/s#-g ##' \
+		-e '/^[ \t]*CFLAGS=/s#-g"#"#' \
+		-e '/^[ \t]*CFLAGS=/s#-O2 ##' \
+		-e '/^[ \t]*CFLAGS=/s#-O2"#"#' \
+		-e '/^[ \t]*USER_CFLAGS=/s#-O2 ##' \
+		-e '/^[ \t]*USER_CFLAGS=/s#-O2"#"#' \
+		configure || die "fixing CFLAGS failed"
+
+	if ! use test ; then
+	sed -i \
+		-e '/^[ \t]*SUBDIRS =/s#tests##' \
+		Makefile.in || die "Removing tests failed"
+	fi
+
+	eapply "${FILESDIR}"/${PN}-2.8.3-solaris10.patch
+	eapply_user
+
+	elibtoolize  # for Solaris
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable asm) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_test() {
+	emake check
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -exec rm -f {} + || die
+}