proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 84 insertions, 0 deletions

diff --git a/sys-libs/libapparmor/libapparmor-2.8.3.ebuild b/sys-libs/libapparmor/libapparmor-2.8.3.ebuild
new file mode 100644
index 000000000000..00b4af1b19ad
--- /dev/null
+++ b/sys-libs/libapparmor/libapparmor-2.8.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_3} )
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools-utils distutils-r1 perl-module versionator
+
+DESCRIPTION="Library to support AppArmor userspace utilities"
+HOMEPAGE="http://apparmor.net/"
+SRC_URI="http://launchpad.net/apparmor/$(get_version_component_range 1-2)/${PV}/+download/apparmor-${PV}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +perl python static-libs"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )"
+
+DEPEND="${RDEPEND}
+	sys-devel/autoconf-archive
+	sys-devel/bison
+	sys-devel/flex
+	doc? ( dev-lang/perl )
+	perl? ( dev-lang/swig )
+	python? ( dev-lang/swig	)"
+
+S=${WORKDIR}/apparmor-${PV}/libraries/${PN}
+
+src_prepare() {
+	rm -r m4 || die "failed to remove bundled macros"
+
+	autotools-utils_src_prepare
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with perl) \
+		$(use_with python)
+	)
+
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile -C src
+
+	use doc && autotools-utils_src_compile -C doc
+	use perl && autotools-utils_src_compile -C swig/perl
+
+	if use python ; then
+		pushd "${BUILD_DIR}"/swig/python > /dev/null
+		emake libapparmor_wrap.c
+		distutils-r1_src_compile
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	autotools-utils_src_install -C src
+	use doc && autotools-utils_src_install -C doc
+
+	if use perl ; then
+		autotools-utils_src_install -C swig/perl
+		perl_set_version
+		insinto "${VENDOR_ARCH}"
+		doins "${BUILD_DIR}"/swig/perl/LibAppArmor.pm
+	fi
+
+	if use python ; then
+		pushd "${BUILD_DIR}"/swig/python > /dev/null
+		distutils-r1_src_install
+		popd > /dev/null
+	fi
+}