sys-cluster/nova: 16.0.4 bup

Package-Manager: Portage-2.3.14, Repoman-2.3.6

2 files changed, 253 insertions, 0 deletions

diff --git a/sys-cluster/nova/Manifest b/sys-cluster/nova/Manifest
index 7defd43d0c54..a96fda376ab2 100644
--- a/sys-cluster/nova/Manifest
+++ b/sys-cluster/nova/Manifest
@@ -1,6 +1,8 @@
 DIST nova-15.0.8.tar.gz 5772381 BLAKE2B 483880fb2571314644b5229b5644ca8090928a799480bdc001382b42b3ab5710ad3e7cc7f28ebbcccd4d385df49b420e6b748454933290b36acd4812aee70040 SHA512 555a57219454f34511870bde1e794a8460a51ac4c11da26608635c3ff629388cdce2792cf67ae466b0e3f8b65ffad61549d294c2672c1f1719913cece82058ef
 DIST nova-16.0.3.tar.gz 10920453 BLAKE2B 5b42039f7d8f1c5e5ffc57befc069d4a19b4cc305be603d76b5cd70aaad4ed96d7df554a58c8865a3105fe532071e87d2df574e07472d475c47b206591730d1b SHA512 fc17a214ac074a12995e75fe7e60dc1a9ab26a0b59e2462926c235e93c0f58b8d96e3043d4187a0f80d2a3feea5bd678d9b41e3496d4e472fa79e4650e14cb1e
+DIST nova-16.0.4.tar.gz 10922054 BLAKE2B 1fb76f0a06149cb67543921cc9f49cd869ebcb85a813079cdde7ed38aded81d0ec5f157b7d031a9269c3df66081cac1d0732286356dc9f8af58de02ba688a9c9 SHA512 8841faca0d3864a7f63f4c6eec637e6676df2b1473dacd0265a34ce4cf8e50bc587892de2f3d54d1e7a499adb8e9c06aca6d7956d010ddabae1ea61c7c5b0581
 DIST nova.conf.sample-15.0.8 344760 BLAKE2B 0c227259325b201740a6a6e0f9a174b8a463ad30b9b09ca819ba23d85ba5471c4e958e23cf96bc8b2dab358521dfc52c216dffc110b46338e80b1821face84e4 SHA512 5c55c752c8752876acbd8d2348abb39d6a8449f637ad2a6515f5c9f4619dbad73c4ae7a6ac4cd164656a0c466ed000a4d68a291050a03a5641fe96b3dd7f732d
 DIST nova.conf.sample-16.0.3 360926 BLAKE2B 0cdfcff1d5faf5803de72b8113085591df4d1c7feb0591df786a5bf0e13ff133c1fcc4a2c3ebfdadf2a60943a7810e18813a00f5f78987daf3c271e3ba627911 SHA512 68f548e998396c7b18692fb3b1e9bf267f9bc06d73f602bb8f20bba426b6ede01e270447906f1685133cdbfd43b76ed5a9913b0167ce70f1ff3debd1ca11d378
+DIST nova.conf.sample-16.0.4 360926 BLAKE2B 0cdfcff1d5faf5803de72b8113085591df4d1c7feb0591df786a5bf0e13ff133c1fcc4a2c3ebfdadf2a60943a7810e18813a00f5f78987daf3c271e3ba627911 SHA512 68f548e998396c7b18692fb3b1e9bf267f9bc06d73f602bb8f20bba426b6ede01e270447906f1685133cdbfd43b76ed5a9913b0167ce70f1ff3debd1ca11d378
 DIST nova.conf.sample-2017.1.9999 344760 BLAKE2B 0c227259325b201740a6a6e0f9a174b8a463ad30b9b09ca819ba23d85ba5471c4e958e23cf96bc8b2dab358521dfc52c216dffc110b46338e80b1821face84e4 SHA512 5c55c752c8752876acbd8d2348abb39d6a8449f637ad2a6515f5c9f4619dbad73c4ae7a6ac4cd164656a0c466ed000a4d68a291050a03a5641fe96b3dd7f732d
 DIST nova.conf.sample-2017.2.9999 360926 BLAKE2B 0cdfcff1d5faf5803de72b8113085591df4d1c7feb0591df786a5bf0e13ff133c1fcc4a2c3ebfdadf2a60943a7810e18813a00f5f78987daf3c271e3ba627911 SHA512 68f548e998396c7b18692fb3b1e9bf267f9bc06d73f602bb8f20bba426b6ede01e270447906f1685133cdbfd43b76ed5a9913b0167ce70f1ff3debd1ca11d378
diff --git a/sys-cluster/nova/nova-16.0.4.ebuild b/sys-cluster/nova/nova-16.0.4.ebuild
new file mode 100644
index 000000000000..bc2f36d667b4
--- /dev/null
+++ b/sys-cluster/nova/nova-16.0.4.ebuild
@@ -0,0 +1,251 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1 eutils linux-info multilib user
+
+DESCRIPTION="Cloud computing fabric controller (main part of an IaaS system) in Python"
+HOMEPAGE="https://launchpad.net/nova"
+SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/nova/pike/nova.conf.sample -> nova.conf.sample-${PV}
+	https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+compute compute-only iscsi +memcached mysql +novncproxy openvswitch postgres +rabbitmq sqlite"
+REQUIRED_USE="
+	!compute-only? ( || ( mysql postgres sqlite ) )
+	compute-only? ( compute !rabbitmq !memcached !mysql !postgres !sqlite )"
+
+CDEPEND="
+	>=dev-python/setuptools-16.0[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-24.0.0[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.0.0[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.0.1[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.0.2[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.0.3[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.1.0[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.1.1[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.2.0[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.3.0[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.3.1[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-34.3.2[${PYTHON_USEDEP}]
+	!~dev-python/setuptools-36.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0"
+DEPEND="
+	${CDEPEND}
+	app-admin/sudo"
+
+RDEPEND="
+	${CDEPEND}
+	compute-only? (
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[sqlite,${PYTHON_USEDEP}]
+	)
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		>=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
+		!~dev-python/pymysql-0.7.7[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		>=dev-python/psycopg-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[${PYTHON_USEDEP}]
+	)
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+	!~dev-python/eventlet-0.20.1[${PYTHON_USEDEP}]
+	<dev-python/eventlet-0.21.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.8[${PYTHON_USEDEP}]
+	!~dev-python/jinja-2.9.0[${PYTHON_USEDEP}]
+	!~dev-python/jinja-2.9.1[${PYTHON_USEDEP}]
+	!~dev-python/jinja-2.9.2[${PYTHON_USEDEP}]
+	!~dev-python/jinja-2.9.3[${PYTHON_USEDEP}]
+	!~dev-python/jinja-2.9.4[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+	!~dev-python/lxml-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/routes-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.6.0[${PYTHON_USEDEP}]
+	!~dev-python/cryptography-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0-r1[${PYTHON_USEDEP}]
+	dev-python/paste[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	<dev-python/prettytable-0.8[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-migrate-0.11.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.13[${PYTHON_USEDEP}]
+	!~dev-python/netaddr-0.7.16[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.0[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	!~dev-python/Babel-2.4.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/jsonschema-2.5.0[${PYTHON_USEDEP}]
+	<dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-cinderclient-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-neutronclient-6.3.0[${PYTHON_USEDEP}]
+	>=dev-python/python-glanceclient-2.8.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/websockify-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-cache-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-4.0.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-4.3.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-2.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.22.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-reports-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.24.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-rootwrap-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-5.24.2[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-5.25.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-1.23.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-privsep-1.9.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-privsep-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-i18n-3.15.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.27.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/os-brick-1.15.2[${PYTHON_USEDEP}]
+	>=dev-python/os-traits-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/os-vif-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/os-win-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/castellan-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/microversion-parse-0.1.2[${PYTHON_USEDEP}]
+	>=dev-python/os-xenapi-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/tooz-1.47.0[${PYTHON_USEDEP}]
+	>=dev-python/cursive-0.1.2[${PYTHON_USEDEP}]
+	>=dev-python/pypowervm-1.1.6[${PYTHON_USEDEP}]
+	dev-python/libvirt-python[${PYTHON_USEDEP}]
+	app-emulation/libvirt[iscsi?]
+	novncproxy? ( www-apps/novnc )
+	sys-apps/iproute2
+	openvswitch? ( net-misc/openvswitch )
+	rabbitmq? ( net-misc/rabbitmq-server )
+	memcached? (
+		net-misc/memcached
+		>=dev-python/python-memcached-1.58
+	)
+	sys-fs/sysfsutils
+	sys-fs/multipath-tools
+	net-misc/bridge-utils
+	compute? (
+		app-cdr/cdrtools
+		sys-fs/dosfstools
+		app-emulation/qemu
+	)
+	iscsi? (
+		sys-fs/lsscsi
+		>=sys-block/open-iscsi-2.0.873-r1
+	)"
+
+#PATCHES=(
+#)
+
+pkg_setup() {
+	linux-info_pkg_setup
+	CONFIG_CHECK_MODULES="BLK_DEV_NBD VHOST_NET IP6_NF_FILTER IP6_NF_IPTABLES IP_NF_TARGET_REJECT \
+	IP_NF_MANGLE IP_NF_TARGET_MASQUERADE NF_NAT_IPV4 IP_NF_FILTER IP_NF_IPTABLES \
+	NF_CONNTRACK_IPV4 NF_DEFRAG_IPV4 NF_NAT_IPV4 NF_NAT NF_CONNTRACK NETFILTER_XTABLES \
+	ISCSI_TCP SCSI_DH DM_MULTIPATH DM_SNAPSHOT"
+	if linux_config_exists; then
+		for module in ${CONFIG_CHECK_MODULES}; do
+			linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled in kernel"
+		done
+	fi
+	enewgroup nova
+	enewuser nova -1 -1 /var/lib/nova nova
+}
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use !compute-only; then
+		for svc in api conductor consoleauth network scheduler spicehtml5proxy xvpvncproxy; do
+			newinitd "${FILESDIR}/nova.initd-2" "nova-${svc}"
+		done
+	fi
+	use compute && newinitd "${FILESDIR}/nova.initd-2" "nova-compute"
+	use novncproxy && newinitd "${FILESDIR}/nova.initd-2" "nova-novncproxy"
+
+	diropts -m 0750 -o nova -g qemu
+	dodir /var/log/nova /var/lib/nova/instances
+	diropts -m 0750 -o nova -g nova
+
+	insinto /etc/nova
+	insopts -m 0640 -o nova -g nova
+	newins "${DISTDIR}/nova.conf.sample-${PV}" "nova.conf.sample"
+	doins "${FILESDIR}/nova-compute.conf"
+	doins "${S}/etc/nova/"*
+	# rootwrap filters
+	insopts -m 0644
+	insinto /etc/nova/rootwrap.d
+	doins "etc/nova/rootwrap.d/api-metadata.filters"
+	doins "etc/nova/rootwrap.d/compute.filters"
+	doins "etc/nova/rootwrap.d/network.filters"
+
+	# add sudoers definitions for user nova
+	insinto /etc/sudoers.d/
+	insopts -m 0600 -o root -g root
+	doins "${FILESDIR}/nova-sudoers"
+
+	if use iscsi ; then
+		# Install udev rules for handle iscsi disk with right links under /dev
+		udev_newrules "${FILESDIR}/openstack-scsi-disk.rules" 60-openstack-scsi-disk.rules
+
+		insinto /etc/nova/
+		doins "${FILESDIR}/scsi-openscsi-link.sh"
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	# copy migration conf file (not coppied on install via setup.py script)
+	insinto "$(python_get_sitedir)/db/sqlalchemy/migrate_repo/"
+	doins "nova/db/sqlalchemy/migrate_repo/migrate.cfg"
+	# copy the CA cert dir (not coppied on install via setup.py script)
+	cp -R "${S}/nova/CA" "${D}/$(python_get_sitedir)/nova/" || die "installing CA files failed"
+}
+
+pkg_postinst() {
+	if use iscsi ; then
+		elog "iscsid needs to be running if you want cinder to connect"
+	fi
+}