net-misc/owncloud-client: add 2.11.1.8438

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index f421c1da28f4..e135d858a8ec 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1,2 +1,3 @@
 DIST ownCloud-2.10.0.6519.tar.xz 5791912 BLAKE2B 3cf02ef89a6af249ab8f9d1b0a4cc899fbb11f49bf47ffb0ce042442da984d8dbf49619cf3344cf1837f1f3437e70f6e6d302f4e4c67a7df5f547368be4252ba SHA512 ab1e8aebefa049a73c436325b3b6e1d03e9a74f93ab6e090adbc71ccdd1cf56297898f004b12312ebba82158f5c2e299d9d0b13c14e291b855dcf267bac490f2
 DIST ownCloud-2.10.1.7389.tar.xz 5598044 BLAKE2B 8558a8a7b7bd4b8a0685b703f0882d6b5619c4902217d40feb4cf5587555b9a85363c7f61834e4c85a84789142fca8c73910fce66544f491ec5968818c816605 SHA512 2a0893d48786b88f8210966a2b6b48f5bdada82818d4115e68ecc6c0c926ba62bc74df03c4ab35eb271aef2f3a43b36b1a6a115585efe3739fd4a6164f9c45a1
+DIST ownCloud-2.11.1.8438.tar.xz 5655380 BLAKE2B da34adafabfc8c2b0bbfdff99a81b56f2d2639b5168b2165a847a6d5a4efe4e86578984c0f0c20564d0978aab18bb1a62330539bdd137f608a5cfc3ff8d84cf0 SHA512 fe38471f62e7233a7ba04f7fd2c7c7231957e6927c39d0bcf3f6f77fd6cbb1223618bbf6a8cc5fa15de10a35c7f07f2f5df0e49acbc2af5fe9333cda2eb41c92
diff --git a/net-misc/owncloud-client/owncloud-client-2.11.1.8438.ebuild b/net-misc/owncloud-client/owncloud-client-2.11.1.8438.ebuild
new file mode 100644
index 000000000000..ef87f857f8d3
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.11.1.8438.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+MY_PN="ownCloud"
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/${MY_PN}/stable/${PV}/source/${MY_PN}-${PV}.tar.xz"
+S=${WORKDIR}/${MY_PN}-${PV}
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dolphin gnome-keyring nautilus test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[gnome-keyring?,qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )"
+
+DEPEND="${RDEPEND}
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules"
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}