net-irc/limnoria: Bump to 20200124

Closes: https://bugs.gentoo.org/762214
Closes: https://bugs.gentoo.org/728010
Closes: https://bugs.gentoo.org/751856
Bug: https://bugs.gentoo.org/716740
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/net-irc/limnoria/Manifest b/net-irc/limnoria/Manifest
index ec19f7578ef3..755ca9043b7e 100644
--- a/net-irc/limnoria/Manifest
+++ b/net-irc/limnoria/Manifest
@@ -1 +1,2 @@
 DIST limnoria-20191123.tar.gz 975077 BLAKE2B b5bc425013a30043c79a5dc53fc346e3b65cafbae154789f43634fc8beb4c7dcfaea34b0c1e22eae28e044eaa2801b0c29ef106fd6e2cc0095e6acbf4c4bf931 SHA512 5822f83a5d7fae0e45e526d9a72c1bbfd2acb7f625cff38e4d6e59222aca4c68204ae03069e991e274b108391cd4feff85783805657554771a7d24789589d14b
+DIST limnoria-20200124.tar.gz 1034653 BLAKE2B 895a0820efcd58429e457e0cb8dbcb864e56a3bce9fab9546cf622aabc7711a015432812c4193d2dabe7a85043c623ce427504c1c8e78530499c8db2c589bd8e SHA512 828c4927e2ce00c012d17f8a2b2d629370c34915e7e4f71de6df67259e643448c33a60d9cf742b2d827e21e17326a8fc20be875eac826edf64406eda906567a4
diff --git a/net-irc/limnoria/limnoria-20200124.ebuild b/net-irc/limnoria/limnoria-20200124.ebuild
new file mode 100644
index 000000000000..e4accb140ca5
--- /dev/null
+++ b/net-irc/limnoria/limnoria-20200124.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="Limnoria"
+MY_P="${MY_PN}-${MY_PV}"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/ProgVal/${MY_PN}.git"
+	EGIT_BRANCH="testing"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Python based extensible IRC infobot and channel bot"
+HOMEPAGE="https://docs.limnoria.net"
+LICENSE="BSD GPL-2+"
+SLOT="0"
+IUSE="crypt ssl test"
+RESTRICT=" !test? ( test )"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/ecdsa[${PYTHON_USEDEP}]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+	!net-irc/supybot
+	!net-irc/supybot-plugins"
+BDEPEND="test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+python_prepare() {
+	einfo "Removing the RSS plugin because of clashes between libxml2's Python3"
+	einfo "bindings and feedparser."
+	rm -r "plugins/RSS" || die
+}
+
+python_test() {
+	pushd "${T}" > /dev/null || die
+	PLUGINS_DIR="${BUILD_DIR}"/lib/supybot/plugins
+	EXCLUDE_PLUGINS=()
+	# intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
+	# runs successfully when running the tests on the installed system
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Unix" )
+	# Runs despite --no-network (GH #1392)
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Aka" )
+	"${EPYTHON}" "${BUILD_DIR}"/scripts/supybot-test "${BUILD_DIR}/../test" \
+		--plugins-dir="${PLUGINS_DIR}" --no-network \
+		--disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
+		|| die "Tests failed under ${EPYTHON}"
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman man/*
+}
+
+pkg_postinst() {
+	elog "Complete user documentation is available at https://limnoria-doc.readthedocs.org/"
+	elog ""
+	elog "Use supybot-wizard to create a configuration file."
+	elog "Run supybot </path/to/config> to use the bot."
+}