net-analyzer/monitoring-plugins: new revision adding radius support.

The monitoring-plugins build system has automagic support for radius
that can be disabled via the --without-radius flag. Doing so allows
(or prevents) the check_radius plugin from being built. This new
revision adds "radius" to IUSE for monitoring-plugins, and builds
check_radius (and pulls in its dependencies) only with USE=radius.

Thanks to Martin Samek who noticed the missing flag.

Closes: https://bugs.gentoo.org/634582
Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 102 insertions, 0 deletions

diff --git a/net-analyzer/monitoring-plugins/monitoring-plugins-2.2-r1.ebuild b/net-analyzer/monitoring-plugins/monitoring-plugins-2.2-r1.ebuild
new file mode 100644
index 000000000000..951992d4302c
--- /dev/null
+++ b/net-analyzer/monitoring-plugins/monitoring-plugins-2.2-r1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic multilib user
+
+DESCRIPTION="50+ standard plugins for Icinga, Naemon, Nagios, Shinken, Sensu"
+HOMEPAGE="https://www.monitoring-plugins.org/"
+SRC_URI="https://www.monitoring-plugins.org/download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~sparc ~x86"
+IUSE="gnutls ipv6 ldap libressl mysql dns fping game postgres radius samba snmp ssh +ssl"
+
+# Most of the plugins use automagic dependencies, i.e. the plugin will
+# get built if the binary it uses is installed. For example, check_snmp
+# will be built only if snmpget from net-analyzer/net-snmp[-minimal] is
+# installed. End result: most of our runtime dependencies are required
+# at build time as well.
+#
+# REAL_DEPEND contains the dependencies that are actually needed to
+# build. DEPEND contains those plus the automagic dependencies.
+#
+REAL_DEPEND="dev-lang/perl
+	ldap? ( net-nds/openldap )
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql:= )
+	ssl? (
+		!gnutls? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:= )
+		)
+		gnutls? ( net-libs/gnutls )
+	)
+	radius? ( net-dialup/freeradius-client )"
+
+DEPEND="${REAL_DEPEND}
+	dns? ( net-dns/bind-tools )
+	game? ( games-util/qstat )
+	fping? ( net-analyzer/fping )
+	samba? ( net-fs/samba )
+	ssh? ( net-misc/openssh )
+	snmp? ( dev-perl/Net-SNMP
+			net-analyzer/net-snmp[-minimal] )"
+
+# Basically everything collides with nagios-plugins.
+RDEPEND="${DEPEND}
+	!net-analyzer/nagios-plugins"
+
+# At least one test is interactive.
+RESTRICT="test"
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	# Use an array to prevent econf from mangling the ping args.
+	local myconf=()
+
+	if use ssl; then
+		myconf+=( $(use_with !gnutls openssl /usr)
+				  $(use_with gnutls gnutls /usr) )
+	else
+		myconf+=( --without-openssl )
+		myconf+=( --without-gnutls )
+	fi
+
+	# The autodetection for these two commands can hang if localhost is
+	# down or ICMP traffic is filtered. Bug #468296.
+	myconf+=( --with-ping-command="/bin/ping -n -U -w %d -c %d %s" )
+
+	if use ipv6; then
+		myconf+=( --with-ping6-command="/bin/ping6 -n -U -w %d -c %d %s" )
+	fi
+
+	econf \
+		$(use_with mysql) \
+		$(use_with ipv6) \
+		$(use_with ldap) \
+		$(use_with postgres pgsql /usr) \
+		$(use_with radius) \
+		"${myconf[@]}" \
+		--libexecdir="/usr/$(get_libdir)/nagios/plugins" \
+		--sysconfdir="/etc/nagios"
+}
+
+DOCS=( ACKNOWLEDGEMENTS AUTHORS CODING ChangeLog FAQ \
+		NEWS README REQUIREMENTS SUPPORT THANKS )
+
+pkg_preinst() {
+	enewgroup nagios
+	enewuser nagios -1 /bin/bash /var/nagios/home nagios
+}
+
+pkg_postinst() {
+	elog "This ebuild has a number of USE flags that determine what you"
+	elog "are able to monitor. Depending on what you want to monitor, some"
+	elog "or all of these USE flags need to be set."
+	elog
+	elog "The plugins are installed in ${EROOT%/}/usr/$(get_libdir)/nagios/plugins"
+}