media-video/unifi-video: bump to EAPI=8

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

1 files changed, 86 insertions, 0 deletions

diff --git a/media-video/unifi-video/unifi-video-3.10.13-r3.ebuild b/media-video/unifi-video/unifi-video-3.10.13-r3.ebuild
new file mode 100644
index 000000000000..a86ef7450ebd
--- /dev/null
+++ b/media-video/unifi-video/unifi-video-3.10.13-r3.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+MY_PV="${PV/_beta/-beta.}"
+DESCRIPTION="UniFi Video Server"
+HOMEPAGE="https://www.ubnt.com/download/unifi-video/"
+SRC_URI="https://dl.ubnt.com/firmwares/ufv/v${MY_PV}/unifi-video.Ubuntu18.04_amd64.v${MY_PV}.deb"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+RESTRICT="mirror"
+
+DEPEND="acct-group/unifi-video
+	acct-user/unifi-video"
+RDEPEND="${DEPEND}
+	dev-db/mongodb
+	dev-java/commons-daemon
+	sys-apps/lsb-release
+	sys-apps/util-linux
+	sys-libs/libcap
+	virtual/jre:1.8"
+
+S=${WORKDIR}
+QA_PREBUILT="usr/lib*/${PN}/lib/*.so usr/lib*/${PN}/bin/*"
+
+src_unpack() {
+	default
+	unpack "${WORKDIR}"/data.tar.gz
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/commons-daemon-move.patch
+	sed -i usr/sbin/${PN} \
+		-e '/require_root$/d' \
+		-e '/update_limits$/d' \
+		-e '/ulimit/d' \
+		-e '/coredump_filter/d' || die
+	default
+}
+
+src_install() {
+	export CODEPATH=/usr/lib/${PN}
+	export DATAPATH=/var/lib/${PN}
+	LOGPATH=${DATAPATH}/logs
+	VARLOGPATH=/var/log/${PN}
+
+	insinto /usr/lib
+	doins -r .${CODEPATH}
+	into /usr
+	dosbin usr/sbin/unifi-video
+
+	dodir ${LOGPATH}
+	fowners -R ${PN}:${PN} ${DATAPATH}
+	dosym ${LOGPATH} ${VARLOGPATH}
+	dosym ${LOGPATH} ${CODEPATH}/logs
+
+	dosym ${DATAPATH} ${CODEPATH}/data
+
+	fperms 500 ${CODEPATH}/bin/ubnt.avtool
+	fperms 500 ${CODEPATH}/bin/evostreamms
+	fperms 500 /usr/sbin/${PN}
+	fowners -R ${PN}:${PN} ${CODEPATH}
+	fperms -R 0400 ${CODEPATH}/lib/
+	fperms 500 ${CODEPATH}/lib/
+
+	echo "CONFIG_PROTECT=\"${DATAPATH}/system.properties\"" > "${T}"/99${PN}
+	doenvd "${T}"/99${PN}
+
+	dosym ../../../bin/mongod ${CODEPATH}/bin/mongod
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+}
+
+pkg_postinst() {
+	if [[ ! -f ${DATAPATH}/system.properties ]]; then
+		cp ${CODEPATH}/etc/system.properties ${DATAPATH}/system.properties
+		echo uuid=$(uuidgen) >> ${DATAPATH}/system.properties
+	fi
+}