media-video/qmplay2: add 24.05.23

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 140 insertions, 0 deletions

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 8eba01fb8505..9da3ebb7c80a 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,3 +1,4 @@
 DIST QMPlay2-src-24.03.16.tar.xz 2013280 BLAKE2B bb241c56a6988659c3810c2d3a922e87f0a7bf324a58d36b4e2efaf5f452c2dbb7aa5a34ff909edc30675f566a2e0c92b1fc1d2524288302cb10fe0a75bfface SHA512 166c4acd2c79cd43693b0c3f8a4802a9b277f519d042a3eabe551d8d277f3f8ec41c74b830c36f0897fe5f247e306e9374eb982441f5a825d355af60b3660495
 DIST QMPlay2-src-24.04.02.tar.xz 2043084 BLAKE2B 481ce8591c362c81569b49a4640e0459d59f31997ab78df86d85551a7e25ae591e80f3c10b73c278f137ac98bba6c89615693f749b9343286e84c4e9811702ca SHA512 958d7dab21e1eecf1b2f18ca980e050c28de4d59f58841b8649b591a4dd9c200e1bb85fa6cd60e4bc317d071b316742ed73502bf3f0d096655aa8d1d2658eae5
 DIST QMPlay2-src-24.04.07.tar.xz 2042608 BLAKE2B 234d21478c090566210f48e62247a22c11f68d7491938d3c59aa201999eb5e0dd54cb9040cf75c655ca0b2337003b7edbe9574e45fb5ca1293e505d0e9824884 SHA512 998929c825db6c92f8a4fa22e998e51ba2aa6d6742d678aef0c380e9131f4de4a9e49c7008b73f8c19b1c8048f17288dd895fc3cade12becb729e5d981e90eac
+DIST QMPlay2-src-24.05.23.tar.xz 2040496 BLAKE2B 98842880382629c0a014d048fa55308809a980c097867d9240321ca21733278439cedebc7a381793d8605f2c29108de6fa4c4ef8daf6261db9ea4248cf0d501b SHA512 a09419fb7f59c30923e51a0673aa219bfb9e9b461775d17c3ac0d683ab145e71f8ecabecee6ace9deb1e0681ea94b8c71682a014bb49d4ee85452e7bce53b390
diff --git a/media-video/qmplay2/qmplay2-24.05.23.ebuild b/media-video/qmplay2/qmplay2-24.05.23.ebuild
new file mode 100644
index 000000000000..54e7842c9a6b
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-24.05.23.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio qt6 sid
+	shaders +taglib vaapi videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )
+"
+
+RDEPEND="
+	media-video/ffmpeg:=[vaapi?]
+	!qt6? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5[X(-),vulkan?]
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+		extensions? ( dev-qt/qtdeclarative:5 )
+		videofilters? ( dev-qt/qtconcurrent:5 )
+	)
+	qt6? (
+		dev-qt/qtbase:6[concurrent,dbus,gui,network,opengl?,ssl,vulkan?,widgets]
+		dev-qt/qt5compat:6
+		dev-qt/qtsvg:6
+		extensions? ( dev-qt/qtdeclarative:6 )
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? ( media-libs/libva[X] )
+	vulkan? ( >=media-libs/vulkan-loader-1.2.133 )
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	!qt6? ( dev-qt/linguist-tools:5 )
+	qt6? ( dev-qt/qttools:6[linguist] )
+"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=$(usex qt6)
+		# core
+		-DUSE_LINK_TIME_OPTIMIZATION=false
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_PM=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}