media-sound/strawberry: drop 1.1.1-r1

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 130 deletions

diff --git a/media-sound/strawberry/Manifest b/media-sound/strawberry/Manifest
index 889cded47790..f1731af7cd77 100644
--- a/media-sound/strawberry/Manifest
+++ b/media-sound/strawberry/Manifest
@@ -1,3 +1,2 @@
-DIST strawberry-1.1.1.tar.xz 11352308 BLAKE2B f43f39f254dce088dd41141715a639f62eb847f0c881e228d5fb1d75a1ee6f70a94fcea732bffda839e2bf7179dc4bf0d8967eb2713c84111339afdc31891bdd SHA512 f44042bc44b6711b8c433b23733c10a13ac6c09f524604fb6d5b71df236cd211a16ea05587af4681ff6859c0af45dc384c67c5f1712182ff692ecf78d6938e19
 DIST strawberry-1.1.2.tar.xz 11354732 BLAKE2B 0f84c37b4fe9fefcea0927473b757388f9e3e9843b2f64ac7ecedc6d8db40cd22161cbc48e5a18b207859d3a27c4659e188cec4f35045643440a809828e136df SHA512 d8059c611d4fda903fc0199fb3b025027dc2bd06fcce943d6f4dc5b934570cf1238653b788325f922e8fa24f2646137cdb2033c8e8e2726ffb21605f4a836489
 DIST strawberry-1.1.3.tar.xz 11347368 BLAKE2B 38e6de5e2723f14973ca922d2bcf593cc445b711e3c437fa425959555b1f942657e32ba62259383720becb945664a60f06fee7468fc03ef4492209e1b0cb6e78 SHA512 666c52f5b912aebc09d86465ee9ac464b8c87e1d20d1650204e305a5d5d1c5b34f97bcbd60ef9bd8c50ed927fe55595ade56c1c5202665931f1a1c58fb7118d3
diff --git a/media-sound/strawberry/strawberry-1.1.1-r1.ebuild b/media-sound/strawberry/strawberry-1.1.1-r1.ebuild
deleted file mode 100644
index cb61111dace6..000000000000
--- a/media-sound/strawberry/strawberry-1.1.1-r1.ebuild
+++ /dev/null
@@ -1,129 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic plocale xdg
-
-PLOCALES="ca cs de es es_AR es_ES es_MX et fi fr hu id it ja ko nb nl pl pt_BR ru sv uk zh_CN"
-
-DESCRIPTION="Modern music player and library organizer based on Clementine and Qt"
-HOMEPAGE="https://www.strawberrymusicplayer.org/"
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://github.com/strawberrymusicplayer/strawberry"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/strawberrymusicplayer/strawberry/releases/download/${PV}/${P}.tar.xz"
-	KEYWORDS="amd64 ~arm64 ~ppc64 x86"
-fi
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="cdda debug +gstreamer ipod moodbar mtp pulseaudio qt6 soup +udisks vlc"
-
-BDEPEND="
-	sys-devel/gettext
-	virtual/pkgconfig
-	!qt6? ( dev-qt/linguist-tools:5 )
-"
-COMMON_DEPEND="
-	dev-db/sqlite:=
-	dev-libs/glib:2
-	dev-libs/icu:=
-	dev-libs/protobuf:=
-	media-libs/alsa-lib
-	media-libs/taglib
-	!qt6? (
-		dev-qt/qtconcurrent:5
-		dev-qt/qtcore:5
-		dev-qt/qtdbus:5
-		dev-qt/qtgui:5
-		dev-qt/qtnetwork:5[ssl]
-		dev-qt/qtsql:5[sqlite]
-		dev-qt/qtwidgets:5
-		dev-qt/qtx11extras:5
-		x11-libs/libX11
-	)
-	qt6? (
-		dev-libs/kdsingleapplication[qt6(+)]
-		dev-qt/qtbase[concurrent,dbus,gui,network,ssl,sql,sqlite,widgets]
-	)
-	cdda? ( dev-libs/libcdio:= )
-	gstreamer? (
-		media-libs/chromaprint:=
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0
-	)
-	ipod? ( media-libs/libgpod )
-	moodbar? ( sci-libs/fftw:3.0 )
-	mtp? ( media-libs/libmtp )
-	pulseaudio? ( media-libs/libpulse )
-	vlc? ( media-video/vlc )
-"
-# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
-RDEPEND="${COMMON_DEPEND}
-	gstreamer? (
-		media-plugins/gst-plugins-meta:1.0
-		soup? ( media-plugins/gst-plugins-soup:1.0 )
-		media-plugins/gst-plugins-taglib:1.0
-	)
-	mtp? ( gnome-base/gvfs[mtp] )
-	udisks? ( sys-fs/udisks:2 )
-"
-DEPEND="${COMMON_DEPEND}
-	dev-cpp/gtest
-	dev-libs/boost
-	!qt6? ( dev-qt/qttest:5 )
-"
-
-DOCS=( Changelog README.md )
-
-REQUIRED_USE="
-	cdda? ( gstreamer )
-	|| ( gstreamer vlc )
-"
-
-src_prepare() {
-	plocale_find_changes "src/translations" "" ".po"
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	# spotify is not in portage
-	local mycmakeargs=(
-		-DBUILD_WERROR=OFF
-		# avoid automagically enabling of ccache (bug #611010)
-		-DCCACHE_EXECUTABLE=OFF
-		-DENABLE_GIO=ON
-		-DLINGUAS="$(plocale_get_locales)"
-		-DENABLE_AUDIOCD="$(usex cdda)"
-		-DENABLE_GSTREAMER="$(usex gstreamer)"
-		-DENABLE_LIBGPOD="$(usex ipod)"
-		-DENABLE_LIBMTP="$(usex mtp)"
-		-DENABLE_LIBPULSE="$(usex pulseaudio)"
-		-DENABLE_MOODBAR="$(usex moodbar)"
-		-DENABLE_MUSICBRAINZ="$(usex gstreamer)"
-		-DENABLE_SONGFINGERPRINTING="$(usex gstreamer)"
-		-DENABLE_SPOTIFY="$(usex gstreamer)"
-		-DENABLE_UDISKS2="$(usex udisks)"
-		-DENABLE_VLC="$(usex vlc)"
-		-DBUILD_WITH_QT6="$(usex qt6)"
-		-DBUILD_WITH_QT5="$(usex !qt6)"
-		-DQT_VERSION_MAJOR="$(usex qt6 6 5)"
-	)
-
-	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
-
-	cmake_src_configure
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if use gstreamer ; then
-		elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
-		elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
-		elog "depending on your preferences"
-	fi
-}