media-plugins/gst-plugins-vaapi: version bump to 0.6.1

Depend on latest gst-1 series as support for 1.2 is deprecated.
Add missing dependency on gst-plugins-bad gl library.

Package-Manager: portage-2.2.23

2 files changed, 61 insertions, 0 deletions

diff --git a/media-plugins/gst-plugins-vaapi/Manifest b/media-plugins/gst-plugins-vaapi/Manifest
index c3a659665982..a6a0720d19cb 100644
--- a/media-plugins/gst-plugins-vaapi/Manifest
+++ b/media-plugins/gst-plugins-vaapi/Manifest
@@ -1,2 +1,3 @@
 DIST gstreamer-vaapi-0.5.10.tar.bz2 1333822 SHA256 0dd236c7bf225322b8934fdba99a7a9e4542566a2acbe7564cdc3ec2c8b73c9d SHA512 bb0c2c29100f2edfdbf76d2de2a554b988779a9fc462788b537f08f6e62f0fdfaa7f12e4e4d49f1abf887533dcbd79bf0c734895bc73f5bc4b0bc3ba0ac07120 WHIRLPOOL 27350341e2899bd50aa8795bde505f4da78f23b9d1615e1a8706516ed482f7f2bae0db8f121b16a6163327cd2323f755b39b6605f16ea725dfabc766ee5ec74e
 DIST gstreamer-vaapi-0.6.0.tar.bz2 1406631 SHA256 f6a4c657606849fb09ee2db778c80278cfa4546e9103862f273c910e208872b8 SHA512 f280655b712ebc14438074a1a659a49417457f34a903c9220a2b7594ef8c6836319f0f22a9bdff5a3899771eb53df1c75de5c3f625094caa0a00964f55025515 WHIRLPOOL a4b75203d8fa53dbd177a7fd08ceb480f10f819985c992d9d384bfeaeb099c8ecbb02d2ac7560f527acd329ac588859e36ab5077067584aea6f951e75b0b905a
+DIST gstreamer-vaapi-0.6.1.tar.bz2 1403160 SHA256 36fc8afeb7ec679ea8df34671a34dba57dcc0b66255fb0991acb485e3efd67b3 SHA512 94dab46414da2b43b9f0fc119c8d901848ad637b1161644888072a733423c60c2b858a37467fc26a4341133c88940304fc70fd328dde9ac0bfba129722771ea8 WHIRLPOOL 49efe4f708810bc786c78f0950ed8249bcbb44113f8a3ce3518ef26eb5168397053314030d324b45346cf50c539d92c0aca5993e949b572a74772da025c4a7af
diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-0.6.1.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-0.6.1.ebuild
new file mode 100644
index 000000000000..c2d0d53f2f8b
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-0.6.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils multilib-minimal
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin"
+HOMEPAGE="https://github.com/01org/gstreamer-vaapi"
+SRC_URI="http://www.freedesktop.org/software/vaapi/releases/${MY_PN}/${MY_PN}-${PV}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="1.0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+drm opengl wayland +X"
+REQUIRED_USE="|| ( drm opengl wayland X )"
+
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-1.6:1.0[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-1.6:1.0[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-bad-1.6:1.0[opengl?,${MULTILIB_USEDEP}]
+	>=x11-libs/libva-1.4.0[drm?,X?,opengl?,wayland?,${MULTILIB_USEDEP}]
+	drm? (
+		>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
+	opengl? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--enable-builtin-libvpx=no \
+		--disable-static \
+		--enable-egl \
+		$(use_enable drm) \
+		$(use_enable opengl glx) \
+		$(use_enable wayland) \
+		$(use_enable X x11)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}