media-libs/libmediainfo: bump to 20.09

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index 9db284ba89cc..fc722694e74d 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1,2 +1,3 @@
 DIST libmediainfo_20.03.tar.xz 1799940 BLAKE2B a0c50ab27e29b010e33334c207872aefc110396401065d3bebdc6cf34aba325453b87e9f1f1ecfe9882bf5f63aaa26f3bbfe3d791cb0c16fa75ca4bb7ff081f0 SHA512 97dd847edf0e290f7ea0153c71a442cc54944bf295f195486f37fa81230cf4463ae2ecc154e73cf75b876b33c038020a9ff082013d57381ab5516a4a2db5ef87
 DIST libmediainfo_20.08.tar.xz 1808948 BLAKE2B 90af512dc5787f01b3600852f275ed0c0e9e1d5393fc60bdb128045e11947873622f1d78f79eba7a4abd46e4537001b66e41f79008ff895680a016e22c5855fc SHA512 c68b7eb906eac2af7b6f588910824ea9a9bd32d4e7b4f8af3579b0e388f5c547583be0ebd1491cdef52dbdb0eca7e2b2731662e48fc66baaddc1e1ca76f385ff
+DIST libmediainfo_20.09.tar.xz 1827744 BLAKE2B 4073da6b85a2871e815a3a374933bae614c25899f8ad77174f63b2055d2220f8b5b785a765f85583289398ce9ade7c014da4d19303b6ed5224e13ffcc2952fdb SHA512 dce5b787866984fd0fefdcb739851212d5a145b657a557fd41c19c7548d32449a3b07d7759bf9a790c5ddebdc9537a0b9f0d5c58b8b2fbb152e456386897a354
diff --git a/media-libs/libmediainfo/libmediainfo-20.09.ebuild b/media-libs/libmediainfo/libmediainfo-20.09.ebuild
new file mode 100644
index 000000000000..617f561cf174
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-20.09.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools eutils flag-o-matic
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="https://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfoLib"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.37[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# tests try to fetch data from online sources
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library
+
+src_prepare() {
+	eapply -p4 "${FILESDIR}"/${PN}-0.7.63-pkgconfig.patch
+	eapply_user
+
+	sed -i 's:-O2::' configure.ac || die
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	find "${ED}" -name '*.la' -delete || die
+}