media-gfx/geeqie: drop USE=gtk3 in stable 1.6

For gtk3 support, use newer 1.6_p20211016

Bug: https://bugs.gentoo.org/829471
Bug: https://bugs.gentoo.org/830232
Package-Manager: Portage-3.0.30, Repoman-3.0.3
RepoMan-Options: --force
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

1 files changed, 91 insertions, 0 deletions

diff --git a/media-gfx/geeqie/geeqie-1.6-r1.ebuild b/media-gfx/geeqie/geeqie-1.6-r1.ebuild
new file mode 100644
index 000000000000..39c6dc86cac5
--- /dev/null
+++ b/media-gfx/geeqie/geeqie-1.6-r1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+LUA_COMPAT=( lua5-{1..3} )
+
+inherit autotools lua-single xdg
+
+DESCRIPTION="A lightweight GTK image viewer forked from GQview"
+HOMEPAGE="http://www.geeqie.org"
+SRC_URI="http://www.geeqie.org/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86"
+IUSE="debug doc exif ffmpegthumbnailer jpeg lcms lirc lua nls pdf tiff xmp"
+
+RDEPEND="
+	virtual/libintl
+	x11-libs/gtk+:2
+	doc? ( app-text/gnome-doc-utils )
+	ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	lirc? ( app-misc/lirc )
+	lua? ( ${LUA_DEPS} )
+	pdf? ( >=app-text/poppler-0.62[cairo] )
+	tiff? ( media-libs/tiff:0 )
+	xmp? ( >=media-gfx/exiv2-0.17:=[xmp] )
+	!xmp? ( exif? ( >=media-gfx/exiv2-0.17:= ) )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
+
+PATCHES=( "${FILESDIR}"/${P}-yelp.patch )
+
+src_prepare() {
+	default
+
+	# Remove -Werror (gcc changes may add new warnings)
+	sed -e '/CFLAGS/s/-Werror //g' -i configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-readmedir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable debug debug-log)
+		$(use_enable ffmpegthumbnailer)
+		--disable-gpu-accel
+		--disable-gtk3
+		$(use_enable jpeg)
+		$(use_enable lcms)
+		$(use_enable lua)
+		$(use_enable lirc)
+		--disable-map
+		$(use_enable nls)
+		$(use_enable pdf)
+		$(use_enable tiff)
+	)
+
+	if use exif || use xmp; then
+		myeconfargs+=( --enable-exiv2 )
+	else
+		myeconfargs+=( --disable-exiv2)
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	rm -f "${D}/usr/share/doc/${PF}/COPYING"
+	# Application needs access to the uncompressed file
+	docompress -x /usr/share/doc/${PF}/README.md
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "Some plugins may require additional packages"
+	elog "- Image rotate plugin: media-gfx/fbida (JPEG), media-gfx/imagemagick (TIFF/PNG)"
+	elog "- RAW images plugin: media-gfx/ufraw"
+}