kde-frameworks/extra-cmake-modules: Drop ECMAddTest patch

Seems like a dead end.

Package-Manager: Portage-2.3.7, Repoman-2.3.3

1 files changed, 60 insertions, 0 deletions

diff --git a/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.37.0-r1.ebuild b/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.37.0-r1.ebuild
new file mode 100644
index 000000000000..a1079a589999
--- /dev/null
+++ b/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.37.0-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+KDE_AUTODEPS="false"
+KDE_DEBUG="false"
+KDE_QTHELP="false"
+KDE_TEST="false"
+inherit kde5 python-any-r1
+
+DESCRIPTION="Extra modules and scripts for CMake"
+HOMEPAGE="https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="doc test"
+
+DEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+	)
+	test? (
+		$(add_qt_dep qtcore)
+		$(add_qt_dep linguist-tools)
+	)
+"
+RDEPEND="
+	app-arch/libarchive[bzip2]
+"
+
+python_check_deps() {
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_HTML_DOCS="$(usex doc)"
+		-DBUILD_MAN_DOCS="$(usex doc)"
+		-DDOC_INSTALL_DIR="/usr/share/doc/${PF}"
+	)
+	use test && mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_PythonModuleGeneration=ON )
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	# ECMToolchainAndroidTest passes but then breaks src_install
+	local myctestargs=(
+		-E "(ECMToolchainAndroidTest)"
+	)
+
+	kde5_src_test
+}