kde-frameworks/extra-cmake-modules: 6.8.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/kde-frameworks/extra-cmake-modules/Manifest b/kde-frameworks/extra-cmake-modules/Manifest
index 0197a1f25a6b..d52fe046c183 100644
--- a/kde-frameworks/extra-cmake-modules/Manifest
+++ b/kde-frameworks/extra-cmake-modules/Manifest
@@ -1,2 +1,3 @@
 DIST extra-cmake-modules-6.6.0.tar.xz 340952 BLAKE2B ea724eb9df8637fdbe2bb34740dbdd6a43d2549ab68eb9a3236d98702449bd847534a6e89c56d95dafbb6b62055505e979a99c4d11fc69c7bff800e5903d80d8 SHA512 2b1a8cf668323386adb33304ca0a78ca7926dbfb51cdc399872d5270e3a79befbb43d0718d0cc862201b6236c9c7005d551ce8704d3972c0ed9485fe0ac19317
 DIST extra-cmake-modules-6.7.0.tar.xz 341336 BLAKE2B 5f63ba006f98527f53cfd989ed26ddafd17ba7666da4b50a3afcbd077037e33b5c52864809ad8f34a07d6d4b0aa15d76db67454c171937f8b7bdefafeef9385d SHA512 f37ce21f32e663e36b9a3f5dd8709b21926b2af08c9dceccd7559ae9ee1a4a1a710a425d5f9d2d8496da70af0258611c9a7ea584ee0f1f4ae4c889262f66d3b0
+DIST extra-cmake-modules-6.8.0.tar.xz 324384 BLAKE2B 64ee8f8265ac68a554bcb2bc0c0fefb038a5442f483b067d64da3af311ee6fdf2403030c98e2df62b71485cf8732416ad55eb47abe34e3c379c7c831ec5bfa26 SHA512 9c523426ff72944a1b0933cf55535b3882b829070d0bbcfc06ee4fafbcf5f4488b595fea1d24a74cfe07cf07d8aef7b8321388db4e1e4011cfa5a5da3a462e31
diff --git a/kde-frameworks/extra-cmake-modules/extra-cmake-modules-6.8.0.ebuild b/kde-frameworks/extra-cmake-modules/extra-cmake-modules-6.8.0.ebuild
new file mode 100644
index 000000000000..ff645083e05b
--- /dev/null
+++ b/kde-frameworks/extra-cmake-modules/extra-cmake-modules-6.8.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+QTMIN=6.7.2
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Extra modules and scripts for CMake"
+HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-arch/libarchive[bzip2]"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+		>=dev-qt/qttools-${QTMIN}:6[assistant]
+	)
+	test? (
+		>=dev-qt/qttools-${QTMIN}:6[linguist]
+		>=dev-qt/qtbase-${QTMIN}:6
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
+	"${FILESDIR}/${PN}-5.93.0-skip-ecm_add_test-early.patch"
+	"${FILESDIR}/${PN}-5.245.0-disable-qmlplugindump.patch"
+	"${FILESDIR}/${PN}-6.5.0-disable-appstreamtest.patch"
+	"${FILESDIR}/${PN}-6.5.0-disable-git-commit-hooks.patch"
+)
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
+		-DBUILD_QTHELP_DOCS=$(usex doc)
+		-DBUILD_HTML_DOCS=$(usex doc)
+		-DBUILD_MAN_DOCS=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# passes, but then breaks src_install
+		ECMToolchainAndroidTest
+		# broken, bug #627806
+		ECMPoQmToolsTest
+		# can not possibly succeed in releases, bug #764953
+		KDEFetchTranslations
+	)
+	# possible race condition with multiple jobs, bug #701854
+	cmake_src_test -j1
+}