kde-apps/kwave: 22.12.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index c3cb14b34fae..e8124d6f2aec 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-22.08.3.tar.xz 6957180 BLAKE2B 0b81eb9d14f7e838c88389eede01790a13adef6a4a76a3f82cbc0b2feab7d1a42e8131cbcfa29fb2ce3ed03ef69f781adbe7ee9ea8d5555cacfaf1a4a57cfe70 SHA512 33515025c4e9de69749cc005f384631a7f4033b3b4404159d0ef6d31f6292bfe30128b73e12d4055dcb599cfb2d5e12750e644d0be1bb6b67158d376fbe5efc5
 DIST kwave-22.12.1.tar.xz 6965616 BLAKE2B 9289a40ab35d7e56736d89ef8c1a09aa0d19703067c5029e932fb0e0841e66de4d917d81c77b30c912843ee8b314a8e63a8268c04871fd5a4855539b1bb0f038 SHA512 b50188acc892150949bf9cec76e7279f467b6e555605c61dcb3d75624b9a438edb70cf70c8c69fd796d6372516716311643bb23a7b05578c45dd451a06d041ad
+DIST kwave-22.12.2.tar.xz 6965772 BLAKE2B a260e287562636a9d555805fcad336951ca9ca22313cb954b12d02a6620ef41d436060efbf39d778b43b832dd70a5de2481c32324b656afbd2ba4f786205f0fe SHA512 1bf0f4f310c0e31fb002817371597aaf1459f2b13de04edc5e6258cc76c7a850284f20e0e539c01878c341080a333b5eb4765326185e53f70d360f65bdc3490b
diff --git a/kde-apps/kwave/kwave-22.12.2.ebuild b/kde-apps/kwave/kwave-22.12.2.ebuild
new file mode 100644
index 000000000000..f02f1fde6847
--- /dev/null
+++ b/kde-apps/kwave/kwave-22.12.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.101.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}