games-action/minetest: Bump to version 0.4.14

Closes: https://github.com/gentoo/gentoo/pull/1469

Signed-off-by: Ian Delaney <idella4@gentoo.org>

2 files changed, 140 insertions, 0 deletions

diff --git a/games-action/minetest/Manifest b/games-action/minetest/Manifest
index 0b610c59d590..eb4977ec1c3c 100644
--- a/games-action/minetest/Manifest
+++ b/games-action/minetest/Manifest
@@ -1,2 +1,3 @@
 DIST minetest-0.4.10.tar.gz 5291236 SHA256 05d15c8e2c8e53ee9d3006e79c2b59200311a7b879220d8b6f6a6fd2acf806b6 SHA512 0d2f2590df530df9bed11a08a3e67dfa39dae1987b8c1f6a4f4f2ace2c40dea3b5afce445e3b2e17b2bd8a426bdd53d717989018f5da531b1eb10965d953c3bf WHIRLPOOL 016c2bc6f9aed44943f238491c445f48013f76a74f9c09e56c1e70e03fa3ded72b042b9dffa0bed81a9dcdc84358a9be88bbf32119dd45a1e2a9873031be1009
 DIST minetest-0.4.13.tar.gz 8366306 SHA256 40bafab13e20e7a550ceaa25ef82dd7b4b8188ee8e8080e1ae9295b82603d5e1 SHA512 e2228f540d3b982515de85635a84e5f157894b5eb1c654da76e1f69e398c69ff0d4d569a5035146b5c80130e9353e020c86c6acc20813075cfd7c9e5c2df2652 WHIRLPOOL 4048db2da06cfb161b794359e4a24573c51553ec98a022295d8de4623c64ac9d235d4cf8ec7a842bdafc91aa147d244ed4aed3991064b5dcb42932fafa42da7b
+DIST minetest-0.4.14.tar.gz 8638852 SHA256 a2a60db3f22d101f78c582f185242e1d913b86a98a7b583cb2261ab715676910 SHA512 a04c03118ac82c78aca6c79cd618efc3ceea7c3f7c7fbcb3fcb1f87a41368a3a41ccdcb350687e745aeedd83af36ff000c30b3d468a5a8e58b68815527df0307 WHIRLPOOL 88b67d2d15c23dbd30650907260f3ac95b69a062a915811d52383da31ec5b7fd80d94b443c287344cd6f1ab71ab09a7127d570023a70afaa1c7217f3aa030c12
diff --git a/games-action/minetest/minetest-0.4.14.ebuild b/games-action/minetest/minetest-0.4.14.ebuild
new file mode 100644
index 000000000000..d5ecd6e76465
--- /dev/null
+++ b/games-action/minetest/minetest-0.4.14.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit cmake-utils eutils gnome2-utils user vcs-snapshot
+
+DESCRIPTION="An InfiniMiner/Minecraft inspired game"
+HOMEPAGE="http://minetest.net/"
+SRC_URI="https://github.com/${PN}/${PN}/tarball/${PV} -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0 OFL-1.1 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+curl dedicated doc +leveldb luajit ncurses nls redis +server +sound spatial +truetype"
+
+RDEPEND="dev-db/sqlite:3
+	sys-libs/zlib
+	curl? ( net-misc/curl )
+	!dedicated? (
+		app-arch/bzip2
+		>=dev-games/irrlicht-1.8-r2
+		dev-libs/gmp:0
+		media-libs/libpng:0
+		virtual/jpeg:0
+		virtual/opengl
+		x11-libs/libX11
+		x11-libs/libXxf86vm
+		sound? (
+			media-libs/libogg
+			media-libs/libvorbis
+			media-libs/openal
+		)
+		truetype? ( media-libs/freetype:2 )
+	)
+	leveldb? ( dev-libs/leveldb )
+	luajit? ( dev-lang/luajit:2 )
+	ncurses? ( sys-libs/ncurses:0 )
+	nls? ( virtual/libintl )
+	redis? ( dev-libs/hiredis )
+	spatial? ( sci-libs/libspatialindex )"
+DEPEND="${RDEPEND}
+	>=dev-games/irrlicht-1.8-r2
+	doc? ( app-doc/doxygen media-gfx/graphviz )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	if use server || use dedicated ; then
+		enewgroup ${PN}
+		enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+	fi
+}
+
+src_prepare() {
+	eapply_user
+	# set paths
+	sed \
+		-e "s#@BINDIR@#/usr/bin#g" \
+		-e "s#@GROUP@#${PN}#g" \
+		"${FILESDIR}"/minetestserver.confd > "${T}"/minetestserver.confd || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex !dedicated)
+		-DCUSTOM_BINDIR="/usr/bin"
+		-DCUSTOM_DOCDIR="/usr/share/doc/${PF}"
+		-DCUSTOM_LOCALEDIR="/usr/share/${PN}/locale"
+		-DCUSTOM_SHAREDIR="/usr/share/${PN}"
+		-DCUSTOM_EXAMPLE_CONF_DIR="/usr/share/doc/${PF}"
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_FREETYPE=$(usex truetype)
+		-DENABLE_GETTEXT=$(usex nls)
+		-DENABLE_GLES=0
+		-DENABLE_LEVELDB=$(usex leveldb)
+		-DENABLE_REDIS=$(usex redis)
+		-DENABLE_SPATIAL=$(usex spatial)
+		-DENABLE_SOUND=$(usex sound)
+		-DENABLE_LUAJIT=$(usex luajit)
+		-DENABLE_CURSES=$(usex ncurses)
+		-DRUN_IN_PLACE=0
+	)
+
+	use dedicated && mycmakeargs+=(
+		-DIRRLICHT_SOURCE_DIR=/the/irrlicht/source
+		-DIRRLICHT_INCLUDE_DIR=/usr/include/irrlicht
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc ; then
+		cmake-utils_src_compile doc
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use server || use dedicated ; then
+		newinitd "${FILESDIR}"/minetestserver.initd minetest-server
+		newconfd "${T}"/minetestserver.confd minetest-server
+	fi
+
+	if use doc ; then
+		cd "${CMAKE_BUILD_DIR}"/doc || die
+		dodoc -r html
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+
+	if ! use dedicated ; then
+		elog
+		elog "optional dependencies:"
+		elog "	games-action/minetest_game (official mod)"
+		elog
+	fi
+
+	if use server || use dedicated ; then
+		elog
+		elog "Configure your server via /etc/conf.d/minetest-server"
+		elog "The user \"minetest\" is created with /var/lib/${PN} homedir."
+		elog "Default logfile is ~/minetest-server.log"
+		elog
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}