summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatt Turner <mattst88@gentoo.org>2022-01-30 13:03:17 -0800
committerMatt Turner <mattst88@gentoo.org>2022-01-30 13:07:24 -0800
commited2c497ad2dd13997997b85c96e52ffd0673fbbd (patch)
tree27647d98c1ced674ddb2641eb2c3b320de1cf4f5 /dev-util/catalyst
parentdev-util/catalyst: Add Python 3.10 compatibility (diff)
downloadgentoo-ed2c497ad2dd13997997b85c96e52ffd0673fbbd.tar.gz
gentoo-ed2c497ad2dd13997997b85c96e52ffd0673fbbd.tar.bz2
gentoo-ed2c497ad2dd13997997b85c96e52ffd0673fbbd.zip
dev-util/catalyst: Version bump to 3.0.21
Closes: https://bugs.gentoo.org/806229 Signed-off-by: Matt Turner <mattst88@gentoo.org>
Diffstat (limited to 'dev-util/catalyst')
-rw-r--r--dev-util/catalyst/Manifest1
-rw-r--r--dev-util/catalyst/catalyst-3.0.21.ebuild73
2 files changed, 74 insertions, 0 deletions
diff --git a/dev-util/catalyst/Manifest b/dev-util/catalyst/Manifest
index 7bf82317e463..7471a715bc46 100644
--- a/dev-util/catalyst/Manifest
+++ b/dev-util/catalyst/Manifest
@@ -1,2 +1,3 @@
DIST catalyst-3.0.18.tar.bz2 621208 BLAKE2B 63f76634b96006ef4a751b0ce166ab36dcba3016234251b2e44e89b43b0c6909e57914007d6287e54584094ff7f064c0251a79f095c87e4c7957925e9d4605cd SHA512 94a30304b242b4e63cc14f34916acd68c03700876ba1cc2f516880f4e8365258de8b62db85cddc9492229414484ba6908edc91991b70b13da0578792b8b96aa3
DIST catalyst-3.0.20.tar.bz2 620395 BLAKE2B 24e1e1def627bccebea4da7b4c0f787d1b7e06cc3a830847896d71e997d859ecc2131a85d328f2d58226bbf2d459ca349d50b1af68b95bb06bfe8e1843f4c4aa SHA512 f2f2b0003a70b7843006155edca0971508d19199dfe803b85477d2f2fd0365304b9e65531cc19bfb06b83fa98dac11960b72001e899bed0f9b55c0f6881a853e
+DIST catalyst-3.0.21.tar.bz2 620472 BLAKE2B 6ecf59edde24cbec6d072a31680b75e2e7f142e267b43783473dc607b189d5091b6ca2b7bd02e88a6528a7bccea8441fce21c74aed6623ec14d701557fb4d267 SHA512 e2c58a562508e25465186a5d9771040ddb9f00104943a6434489e5ef01da220ac0330339f741d023717c8d1df6ec2bf765654fabe4097d93d3086ef9005a294c
diff --git a/dev-util/catalyst/catalyst-3.0.21.ebuild b/dev-util/catalyst/catalyst-3.0.21.ebuild
new file mode 100644
index 000000000000..282eccf985ea
--- /dev/null
+++ b/dev-util/catalyst/catalyst-3.0.21.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == *9999* ]]; then
+ SRC_ECLASS="git-r3"
+ EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/catalyst.git"
+ EGIT_BRANCH="master"
+else
+ SRC_URI="https://gitweb.gentoo.org/proj/catalyst.git/snapshot/${P}.tar.bz2"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 ${SRC_ECLASS}
+
+DESCRIPTION="Release metatool used for creating releases based on Gentoo Linux"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Catalyst"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="ccache doc +iso system-bootloader"
+
+DEPEND="
+ app-text/asciidoc
+ >=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+ dev-python/fasteners[${PYTHON_USEDEP}]
+"
+RDEPEND="
+ >=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+ dev-python/fasteners[${PYTHON_USEDEP}]
+ >=dev-python/pydecomp-0.3[${PYTHON_USEDEP}]
+ app-arch/lbzip2
+ app-crypt/shash
+ sys-fs/dosfstools
+ || (
+ app-arch/tar[xattr]
+ app-arch/libarchive[xattr]
+ )
+ amd64? ( >=sys-boot/syslinux-3.72 )
+ x86? ( >=sys-boot/syslinux-3.72 )
+ ccache? ( dev-util/ccache )
+ iso? ( app-cdr/cdrtools )
+ kernel_linux? ( app-misc/zisofs-tools >=sys-fs/squashfs-tools-2.1 )
+"
+PDEPEND="system-bootloader? ( >=sys-apps/memtest86+-5.01-r4
+ sys-boot/grub:2
+ amd64? ( sys-boot/grub[grub_platforms_efi-32,grub_platforms_efi-64] )
+ x86? ( sys-boot/grub[grub_platforms_efi-32] )
+ sys-boot/syslinux
+ sys-boot/shim )"
+
+python_prepare_all() {
+ python_setup
+ echo VERSION="${PV}" "${PYTHON}" setup.py set_version
+ VERSION="${PV}" "${PYTHON}" setup.py set_version || die
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ # build the man pages and docs
+ emake
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ if use doc; then
+ dodoc files/HOWTO.html files/docbook-xsl.css
+ fi
+}