dev-scheme/owl-lisp: new package; add version 0.2 and live

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-scheme/owl-lisp/owl-lisp-0.2.ebuild b/dev-scheme/owl-lisp/owl-lisp-0.2.ebuild
new file mode 100644
index 000000000000..95d2e9242438
--- /dev/null
+++ b/dev-scheme/owl-lisp/owl-lisp-0.2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# NOTICE: Because it is "purely functional" it is not scheme-compatible ootb
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Purely functional dialect of Scheme"
+HOMEPAGE="https://haltp.org/posts/owl.html"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/owl-lisp/owl.git"
+else
+	SRC_URI="https://gitlab.com/owl-lisp/owl/-/archive/v0.2/owl-v${PV}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/owl-v${PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+src_prepare() {
+	default
+
+	sed -i 's|make bin/vm|$(MAKE) bin/vm|g' ./Makefile || die
+}
+
+src_compile(){
+	emake CC=$(tc-getCC) CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" owl
+}
+
+src_install() {
+	einstalldocs
+
+	dobin ./bin/ol
+	newbin ./bin/vm ovm
+
+	doman ./doc/*.1
+}