dev-scheme/chicken: update to EAPI 8

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Akinori Hattori <hattya@gentoo.org>

3 files changed, 97 insertions, 100 deletions

diff --git a/dev-scheme/chicken/chicken-4.13.0-r1.ebuild b/dev-scheme/chicken/chicken-4.13.0-r1.ebuild
deleted file mode 100644
index a5909e3096ea..000000000000
--- a/dev-scheme/chicken/chicken-4.13.0-r1.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit versionator
-
-MY_PV=$(get_version_component_range 1-3)
-DESCRIPTION="Scheme interpreter and native Scheme to C compiler"
-HOMEPAGE="https://www.call-cc.org/"
-SRC_URI="https://code.call-cc.org/releases/${MY_PV}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 ppc ppc64 x86"
-IUSE="doc"
-
-DEPEND=""
-RDEPEND=""
-
-src_prepare() {
-	default
-
-	#Because chicken's Upstream is in the habit of using variables that
-	#portage also uses :( eg. $ARCH and $A
-	sed "s,A\(\s?=\|)\),chicken&," \
-		-i Makefile.cross-linux-mingw defaults.make rules.make || die
-	sed "s,ARCH,zARCH," \
-		-i Makefile.* defaults.make rules.make || die
-	sed -e "s,\$(PREFIX)/lib,\$(PREFIX)/$(get_libdir)," \
-		-e "s,\$(DATADIR)/doc,\$(SHAREDIR)/doc/${PF}," \
-		-i defaults.make || die
-
-	if ! use doc; then
-		rm -rf manual || die
-		# Without this Makefile tries to re-bootstrap the compiler
-		touch build-version.c
-	fi
-}
-
-src_compile() {
-	emake -j1 PLATFORM=linux PREFIX=/usr C_COMPILER_OPTIMIZATION_OPTIONS="${CFLAGS}" \
-		LINKER_OPTIONS="${LDFLAGS}" \
-		HOSTSYSTEM="${CBUILD}"
-}
-
-src_test() {
-	cd tests
-	./runtests.sh || die
-}
-
-src_install() {
-	# still can't run make in parallel for the install target
-	emake -j1 PLATFORM=linux PREFIX=/usr DESTDIR="${D}" HOSTSYSTEM="${CBUILD}" \
-		LINKER_OPTIONS="${LDFLAGS}" install
-
-	rm "${D}"/usr/share/doc/${PF}/LICENSE || die
-
-	# README is installed by Makefile
-	dodoc NEWS
-
-	# Let portage track this file (created later)
-	touch "${D}"/usr/$(get_libdir)/chicken/8/modules.db || die
-}
-
-pkg_postinst() {
-	# Create modules.db file in ${ROOT}
-	chicken-install -update-db || die
-}
diff --git a/dev-scheme/chicken/chicken-4.13.0-r2.ebuild b/dev-scheme/chicken/chicken-4.13.0-r2.ebuild
new file mode 100644
index 000000000000..9a1a6c4639ef
--- /dev/null
+++ b/dev-scheme/chicken/chicken-4.13.0-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+DESCRIPTION="Scheme interpreter and native Scheme to C compiler"
+HOMEPAGE="https://www.call-cc.org/"
+SRC_URI="https://code.call-cc.org/releases/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 ppc ppc64 x86"
+IUSE="doc"
+
+RDEPEND=""
+DEPEND=""
+
+src_prepare() {
+	default
+
+	# because chicken's upstream is in the habit of using variables that
+	# portage also uses :( eg. $ARCH and $A
+	sed -i \
+		-e "s/A\([[:space:]]*?=\|)\)/z&/" \
+		-e "s/ARCH/z&/" \
+		-e "/LICENSE /d" \
+		Makefile.* {defaults,rules}.make || die
+	sed -i \
+		-e "s|\$(PREFIX)/lib|\$(PREFIX)/$(get_libdir)|" \
+		-e "s|\$(DATADIR)/doc|\$(SHAREDIR)/doc/${PF}|" \
+		defaults.make || die
+
+	use doc || sed -i "/\$(SEP)manual/d" rules.make || die
+}
+
+src_compile() {
+	emake -j1 \
+		PLATFORM="linux" \
+		PREFIX="${EPREFIX}/usr" \
+		C_COMPILER_OPTIMIZATION_OPTIONS="${CFLAGS}" \
+		HOSTSYSTEM="${CBUILD}" \
+		LINKER_OPTIONS="${LDFLAGS}"
+}
+
+src_test() {
+	cd tests && ./runtests.sh || die
+}
+
+src_install() {
+	emake -j1 \
+		PLATFORM="linux" \
+		PREFIX="${EPREFIX}/usr" \
+		HOSTSYSTEM="${CBUILD}" \
+		LINKER_OPTIONS="${LDFLAGS}" \
+		DESTDIR="${D}" \
+		install
+	einstalldocs
+
+	# let portage track this file (created later)
+	touch "${ED}"/usr/$(get_libdir)/${PN}/8/modules.db || die
+}
+
+pkg_postinst() {
+	# create modules.db file in ${ROOT}
+	chicken-install -update-db || die
+}
diff --git a/dev-scheme/chicken/chicken-5.2.0.ebuild b/dev-scheme/chicken/chicken-5.2.0.ebuild
index 6d7cd0c4131a..93fd8f4559b2 100644
--- a/dev-scheme/chicken/chicken-5.2.0.ebuild
+++ b/dev-scheme/chicken/chicken-5.2.0.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI="8"
 
 DESCRIPTION="Scheme interpreter and native Scheme to C compiler"
 HOMEPAGE="https://www.call-cc.org/"
@@ -12,55 +12,55 @@ SLOT="0"
 KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86"
 IUSE="doc"
 
-DEPEND=""
 RDEPEND=""
+DEPEND=""
 
 src_prepare() {
 	default
 
-	# Because chicken's Upstream is in the habit of using variables that
+	# because chicken's upstream is in the habit of using variables that
 	# portage also uses :( eg. $ARCH and $A
-	sed "s,A\(\s?=\|)\),chicken&," \
-		-i Makefile.cross-linux-mingw defaults.make rules.make || die
-	sed "s,ARCH,zARCH," \
-		-i Makefile.* defaults.make rules.make || die
-	sed -e "s,\$(PREFIX)/lib,\$(PREFIX)/$(get_libdir)," \
-		-e "s,\$(DATADIR)/doc,\$(SHAREDIR)/doc/${PF}," \
-		-i defaults.make || die
+	sed -i \
+		-e "s/A\([[:space:]]*?=\|)\)/z&/" \
+		-e "s/ARCH/z&/" \
+		-e "/LICENSE /d" \
+		Makefile.* {defaults,rules}.make || die
+	sed -i \
+		-e "s|\$(PREFIX)/lib|\$(PREFIX)/$(get_libdir)|" \
+		-e "s|\$(DATADIR)/doc|\$(SHAREDIR)/doc/${PF}|" \
+		defaults.make || die
 
-	if ! use doc; then
-		rm -rf manual-html || die
-		# Without this Makefile tries to re-bootstrap the compiler
-		touch build-version.c
-	fi
+	use doc || sed -i "/\$(SEP)manual/d" rules.make || die
 }
 
 src_compile() {
-	emake -j1 PLATFORM=linux PREFIX=/usr C_COMPILER_OPTIMIZATION_OPTIONS="${CFLAGS}" \
-		LINKER_OPTIONS="${LDFLAGS}" \
-		HOSTSYSTEM="${CBUILD}"
+	emake -j1 \
+		PLATFORM="linux" \
+		PREFIX="${EPREFIX}/usr" \
+		C_COMPILER_OPTIMIZATION_OPTIONS="${CFLAGS}" \
+		HOSTSYSTEM="${CBUILD}" \
+		LINKER_OPTIONS="${LDFLAGS}"
 }
 
 src_test() {
-	cd tests
-	./runtests.sh || die
+	cd tests && ./runtests.sh || die
 }
 
 src_install() {
-	# still can't run make in parallel for the install target
-	emake -j1 PLATFORM=linux PREFIX=/usr DESTDIR="${D}" HOSTSYSTEM="${CBUILD}" \
-		LINKER_OPTIONS="${LDFLAGS}" install
-
-	rm "${D}"/usr/share/doc/${PF}/LICENSE || die
-
-	# README is installed by Makefile
-	dodoc NEWS
+	emake -j1 \
+		PLATFORM="linux" \
+		PREFIX="${EPREFIX}/usr" \
+		HOSTSYSTEM="${CBUILD}" \
+		LINKER_OPTIONS="${LDFLAGS}" \
+		DESTDIR="${D}" \
+		install
+	einstalldocs
 
-	# Let portage track this file (created later)
-	touch "${D}"/usr/$(get_libdir)/chicken/11/modules.db || die
+	# let portage track this file (created later)
+	touch "${ED}"/usr/$(get_libdir)/${PN}/11/modules.db || die
 }
 
 pkg_postinst() {
-	# Create modules.db file in ${ROOT}
+	# create modules.db file in ${ROOT}
 	chicken-install -update-db || die
 }