dev-python/sphinx: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 126 deletions

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 478df0cf386c..eaf952976005 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,4 +1,3 @@
-DIST sphinx-5.3.0.gh.tar.gz 6873479 BLAKE2B c57ede5e3d83447c6152d050d45df73bced62ce0cdcd84ea6316a48bff072590ad036c469dee053a9dc5eb1a7ae53b350aa25b5fe14c3378dc6543186552f720 SHA512 6877635d46f2e1f2b4cf4edaca463d85bf740a13bbeb867486efd57904aacc42626e6a4f58ad971e50808d31391d068702c4f2910a95e5c86dbd68d87e2552c8
 DIST sphinx-6.2.1.gh.tar.gz 6729925 BLAKE2B 621ead516dc17cc632e9e752b56b5432547b6a051ede353d690dca0769664fc1c1335ec948f4035cb8c4307a563b4928d2587de3f3ec8d89dacf829a8fd5b95f SHA512 ba56fb9672dc2e156b6cfd0fc2252a989d44b199946a371ec5f1cda5840836b3a58e267ac0973f522479b472dbb07c6c2d7ae6b0c63c9adfbe82d36bd59a9465
 DIST sphinx-7.0.1.gh.tar.gz 6712916 BLAKE2B 7e30804eb5c24559c8ca30e5d8943ad78b426f94c3008ec74de6a541a71a7835d4e83dd69d84df04778f6246840209847ce103863b4dd4109e01bc3a5a50fd84 SHA512 6489778c4953b2c2d9972fa3f07fdb3b361b441e2c9f47282ec9c47f70446e3df66e434690ba816cc6f98838056001d2518f9bd1235e8b07ddba3c1d03a57b76
 DIST sphinx-7.1.0.gh.tar.gz 6882321 BLAKE2B dfa644b33e0dc97acb04470da452f184cdc377e0c07a58e2e504b425becbc114eac503559ceb7dc81b54d31e89587a8f8f3ecb11df073a949f08d0281ca21a3c SHA512 707a9f36e7c8f0dd0f0f6c3d81dff67e3c996fb8b9daac0eec240200828347ddfde3d374ca45286cd41bdc6a88d89012b606b217304f41b71661ee0d4acc9bbe
diff --git a/dev-python/sphinx/sphinx-5.3.0.ebuild b/dev-python/sphinx/sphinx-5.3.0.ebuild
deleted file mode 100644
index ddbbb78e4580..000000000000
--- a/dev-python/sphinx/sphinx-5.3.0.ebuild
+++ /dev/null
@@ -1,125 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=flit
-PYTHON_COMPAT=( python3_{9..11} pypy3 )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1
-
-DESCRIPTION="Python documentation generator"
-HOMEPAGE="
-	https://www.sphinx-doc.org/
-	https://github.com/sphinx-doc/sphinx/
-	https://pypi.org/project/Sphinx/
-"
-SRC_URI="
-	https://github.com/sphinx-doc/sphinx/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="doc latex"
-
-RDEPEND="
-	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
-	>=dev-python/Babel-2.9[${PYTHON_USEDEP}]
-	<dev-python/docutils-0.20[${PYTHON_USEDEP}]
-	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
-	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.12[${PYTHON_USEDEP}]
-	>=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
-	>=dev-python/snowballstemmer-2.0[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
-	>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
-	>=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
-	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
-	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
-	latex? (
-		dev-texlive/texlive-latexextra
-		dev-texlive/texlive-luatex
-		app-text/dvipng
-	)
-	!dev-python/namespace-sphinxcontrib
-"
-BDEPEND="
-	doc? (
-		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
-		media-gfx/graphviz
-	)
-	test? (
-		app-text/dvipng
-		dev-python/cython[${PYTHON_USEDEP}]
-		dev-python/html5lib[${PYTHON_USEDEP}]
-		dev-texlive/texlive-fontsextra
-		dev-texlive/texlive-latexextra
-		dev-texlive/texlive-luatex
-		virtual/imagemagick-tools[jpeg,png,svg]
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
-	"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
-)
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	# disable internet access
-	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
-		doc/conf.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile_all() {
-	if use doc; then
-		esetup.py build_sphinx
-		HTML_DOCS=( build/sphinx/html/. )
-	fi
-}
-
-python_test() {
-	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
-	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
-
-	local EPYTEST_DESELECT=(
-		# these tests require Internet access
-		tests/test_build_latex.py::test_latex_images
-		tests/test_build_linkcheck.py::test_defaults
-		tests/test_build_linkcheck.py::test_defaults_json
-		tests/test_build_linkcheck.py::test_anchors_ignored
-		# TODO
-		tests/test_ext_autodoc_autoclass.py::test_classes
-		tests/test_ext_autodoc_autofunction.py::test_classes
-		tests/test_ext_inheritance_diagram.py::test_import_classes
-		# looks like a bug in lualatex
-		"tests/test_build_latex.py::test_build_latex_doc[lualatex-howto]"
-		"tests/test_build_latex.py::test_build_latex_doc[lualatex-manual]"
-	)
-	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
-		tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
-		tests/test_ext_autodoc.py::test_automethod_for_builtin
-		tests/test_ext_autodoc.py::test_cython
-		tests/test_ext_autodoc.py::test_partialfunction
-		tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
-		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
-		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
-		tests/test_ext_autodoc_autofunction.py::test_builtin_function
-		tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
-		tests/test_ext_autodoc_automodule.py::test_automodule_inherited_members
-		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
-		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
-		tests/test_util_inspect.py::test_isattributedescriptor
-		tests/test_util_typing.py::test_stringify_type_hints_pep_585
-	)
-
-	epytest
-}