dev-python/python-ldap: add 3.4.0_p20220420

Snapshot because a bunch of commits were needed to fix OpenLDAP 2.6+
compat and then there were some serious bugfixes too.

Closes: https://bugs.gentoo.org/835637
Signed-off-by: Sam James <sam@gentoo.org>

4 files changed, 102 insertions, 5 deletions

diff --git a/dev-python/python-ldap/Manifest b/dev-python/python-ldap/Manifest
index 99a3c3c496f9..86ce9bf4aa32 100644
--- a/dev-python/python-ldap/Manifest
+++ b/dev-python/python-ldap/Manifest
@@ -1 +1,2 @@
 DIST python-ldap-3.4.0.tar.gz 376169 BLAKE2B f514ddb6267fd8c21a1c4595669921a1256a8087a3a272b3751636313e7d79de9d34f4213aa57128679dc5a93db4ef7a71f7f92894a1802deb8c2ca9dfd92fe2 SHA512 d10c10f1d416a0f67e7669c6c0b5460a3484bc31f4af471d581a9207689e5687c08d1ad78ba8d47e0ce0c35d24d79e4b848b4c503534f211a36c1b882bee3605
+DIST python-ldap-3.4.0_p20220420.tar.gz 377780 BLAKE2B 433178138587dc09bfe1e6a8e894c001baf6e07c76266ca9d7c56b279f9e9ca5a642528a5869a837a9ee5576a2cf17afdeea313b4a8bc930926397738d6a5daf SHA512 0dfe8ff4737a630a08c7cd4d94f30c78fd1e0558ffc0609439d95ef064b72aef9d4ec4cdc0d40aaf1fc46396bdc0cbbdf0bf3cf6bb5e94bf8a9e3083b9ba1bf4
diff --git a/dev-python/python-ldap/python-ldap-3.4.0-r1.ebuild b/dev-python/python-ldap/python-ldap-3.4.0-r1.ebuild
index 51eca9aab9f6..5c1563d0eb7e 100644
--- a/dev-python/python-ldap/python-ldap-3.4.0-r1.ebuild
+++ b/dev-python/python-ldap/python-ldap-3.4.0-r1.ebuild
@@ -18,7 +18,7 @@ if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
 else
 	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-solaris"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x86-solaris"
 fi
 
 LICENSE="MIT PSF-2"
diff --git a/dev-python/python-ldap/python-ldap-3.4.0_p20220420.ebuild b/dev-python/python-ldap/python-ldap-3.4.0_p20220420.ebuild
new file mode 100644
index 000000000000..488fa3e27563
--- /dev/null
+++ b/dev-python/python-ldap/python-ldap-3.4.0_p20220420.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+inherit distutils-r1
+
+DESCRIPTION="Various LDAP-related Python modules"
+HOMEPAGE="https://www.python-ldap.org/en/latest/
+	https://pypi.org/project/python-ldap/
+	https://github.com/python-ldap/python-ldap"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/python-ldap/python-ldap.git"
+	inherit git-r3
+else
+	# Snapshot for various new OpenLDAP fixes, bug #835637
+	# (There were a bunch of followup commits and general other
+	# serious bugfixes we want.)
+	MY_COMMIT="7f30c4721ea2ca4373ed7860e6467781f0afa758"
+
+	#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	SRC_URI="https://github.com/python-ldap/python-ldap/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-${MY_COMMIT}
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x86-solaris"
+fi
+
+LICENSE="MIT PSF-2"
+SLOT="0"
+IUSE="examples sasl ssl"
+
+RDEPEND="
+	>=dev-python/pyasn1-0.3.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.1.5[${PYTHON_USEDEP}]
+	net-nds/openldap:=[sasl?,ssl?]
+"
+# We do not link against cyrus-sasl but we use some
+# of its headers during the build.
+DEPEND="
+	net-nds/openldap:=[sasl?,ssl?]
+	sasl? ( >=dev-libs/cyrus-sasl-2.1 )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx Doc
+
+python_prepare_all() {
+	# The live ebuild won't compile if setuptools_scm < 1.16.2 is installed
+	# https://github.com/pypa/setuptools_scm/issues/228
+	if [[ ${PV} == *9999* ]]; then
+		rm -r .git || die
+	fi
+
+	if ! use sasl; then
+		sed -i 's/HAVE_SASL//g' setup.cfg || die
+	fi
+	if ! use ssl; then
+		sed -i 's/HAVE_TLS//g' setup.cfg || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Run all tests which don't require slapd
+	local EPYTEST_IGNORE=(
+		t_bind.py
+		t_cext.py
+		t_edit.py
+		t_ldapobject.py
+		t_ldap_options.py
+		t_ldap_sasl.py
+		t_ldap_schema_subentry.py
+		t_ldap_syncrepl.py
+		t_slapdobject.py
+	)
+	pushd Tests >/dev/null || die
+	epytest
+	popd > /dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+	python_optimize
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r Demo/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/python-ldap/python-ldap-9999.ebuild b/dev-python/python-ldap/python-ldap-9999.ebuild
index a01b853838d7..6bcb8bc92611 100644
--- a/dev-python/python-ldap/python-ldap-9999.ebuild
+++ b/dev-python/python-ldap/python-ldap-9999.ebuild
@@ -2,8 +2,9 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
-PYTHON_COMPAT=( pypy3 python3_{7..10} )
 
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
 inherit distutils-r1
 
 DESCRIPTION="Various LDAP-related Python modules"
@@ -22,16 +23,15 @@ LICENSE="MIT PSF-2"
 SLOT="0"
 IUSE="examples sasl ssl"
 
-# < dep on openldap for bug #835637, ldap_r is gone
 RDEPEND="
 	>=dev-python/pyasn1-0.3.7[${PYTHON_USEDEP}]
 	>=dev-python/pyasn1-modules-0.1.5[${PYTHON_USEDEP}]
-	<net-nds/openldap-2.6:=[sasl?,ssl?]
+	net-nds/openldap:=[sasl?,ssl?]
 "
 # We do not link against cyrus-sasl but we use some
 # of its headers during the build.
 DEPEND="
-	<net-nds/openldap-2.6:=[sasl?,ssl?]
+	net-nds/openldap:=[sasl?,ssl?]
 	sasl? ( >=dev-libs/cyrus-sasl-2.1 )
 "