dev-python/pygobject: Bump to 3.42.2

Now with a test phase that no longer crashes for me, and fancy
distutils-r1 PEP517=no mode!

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/dev-python/pygobject/Manifest b/dev-python/pygobject/Manifest
index 86e870e272e8..4ce0bee6bd04 100644
--- a/dev-python/pygobject/Manifest
+++ b/dev-python/pygobject/Manifest
@@ -1 +1,2 @@
 DIST pygobject-3.42.1.tar.xz 557904 BLAKE2B 5264c1b187210622548203e0df5089262ea0b3e93d9e46679030b4722e74f1993f200cfe9357c389357902bcdfdb13c8fd9cc9d6efa3b5fa0f730c3b54017fe5 SHA512 b044d395f8334057be632fd56f670ae8405d9fc375bcbd7a0a3b2dcfb8efb06bad45e62e92d2ee5432e503642dba11d6f9bf91f26bf135fa5f9a871657105a18
+DIST pygobject-3.42.2.tar.xz 558724 BLAKE2B 3e98cf52e818eff42beb8b6120ee8eb4cbe3a6f49670d355e1081b71d411bc93fc701cc37108a321cfcc19698c39b8b61cce5a9369d871da58fd2a2c0455fb96 SHA512 eb604f839e0702e8aeff0f19665e44c05c56cae02ce892e9ab8a95ddb0d5d0216182d0c9a0059fc8e05990c0d5707f2f7456d8924bbfb95ce1d9a42908ac0119
diff --git a/dev-python/pygobject/pygobject-3.42.2.ebuild b/dev-python/pygobject/pygobject-3.42.2.ebuild
new file mode 100644
index 000000000000..217ae21f2c4a
--- /dev/null
+++ b/dev-python/pygobject/pygobject-3.42.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org meson virtualx xdg distutils-r1
+
+DESCRIPTION="Python bindings for GObject Introspection"
+HOMEPAGE="https://pygobject.readthedocs.io/"
+
+LICENSE="LGPL-2.1+"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+cairo examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.56:2
+	>=dev-libs/gobject-introspection-1.56:=
+	dev-libs/libffi:=
+	cairo? (
+		>=dev-python/pycairo-1.16.0[${PYTHON_USEDEP}]
+		x11-libs/cairo[glib]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-libs/atk[introspection]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		x11-libs/gdk-pixbuf:2[introspection,jpeg]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection]
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+python_configure() {
+	meson_src_configure \
+		$(meson_feature cairo pycairo) \
+		$(meson_use test tests) \
+		-Dpython="${EPYTHON}"
+}
+
+python_compile() {
+	meson_src_compile
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x GIO_USE_VFS="local" # prevents odd issues with deleting ${T}/.gvfs
+	local -x GIO_USE_VOLUME_MONITOR="unix" # prevent udisks-related failures in chroots, bug #449484
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x XDG_CACHE_HOME="${T}/${EPYTHON}"
+	meson_src_test --timeout-multiplier 3 || die "test failed for ${EPYTHON}"
+}
+
+python_install() {
+	meson_src_install
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}