proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

6 files changed, 205 insertions, 0 deletions

diff --git a/dev-python/mako/Manifest b/dev-python/mako/Manifest
new file mode 100644
index 000000000000..5553b56b85ee
--- /dev/null
+++ b/dev-python/mako/Manifest
@@ -0,0 +1,2 @@
+DIST Mako-0.7.3.tar.gz 401787 SHA256 5e1d17fbd1aed57ebeea74ee3809015b121e142d73069066a113a125a4ec2ef5 SHA512 3134a05fcacb5d8e41ebab3bedb6c1a31eec94afb56f2c8319fee4b749930fcc7df5ed86e0de26cafbaea966b920921e29788f1c6ba5810eedb4d98f322085f9 WHIRLPOOL 8d3011b472a4bd04c4ef0ddad4767357bd1c570228702e900c956582c2e1e7e668765a34e4e450e18b8a1e0562d9b024ee1ae8b82efc891023154cf442f16d8a
+DIST Mako-1.0.0.tar.gz 470006 SHA256 a3cd72cfef507204b50f74ffcbfcfde7e856437891d3f6cfe780866986d006fe SHA512 81a6b7637e26d561350a591e3490e7140db218ae7f6b43fec8fca5b767fc6e57d0e8cc901d28fecb9863b2170c824a35c578a94579f991359fa0873f62ec578a WHIRLPOOL aa27b63e3832f03120312fbfec939b05606081e67a5cb4c9a056c27259631c2e159cf7506292d44e2c17c5950d7e4255d19f4beba78502bdbb52fbf11e1a872c
diff --git a/dev-python/mako/files/test-fix.patch b/dev-python/mako/files/test-fix.patch
new file mode 100644
index 000000000000..3792e3e30f5b
--- /dev/null
+++ b/dev-python/mako/files/test-fix.patch
@@ -0,0 +1,11 @@
+diff -ur Mako-0.7.0.orig/test/test_template.py Mako-0.7.0/test/test_template.py
+--- test/test_template.py	2012-03-31 07:52:02.000000000 +0800
++++ test/test_template.py	2012-04-11 20:25:23.797168875 +0800
+@@ -1,5 +1,5 @@
+ # -*- coding: utf-8 -*-
+-
++from __future__ import with_statement
+ from mako.template import Template, ModuleTemplate
+ from mako.lookup import TemplateLookup
+ from mako.ext.preprocessors import convert_comments
+
diff --git a/dev-python/mako/mako-0.7.3-r1.ebuild b/dev-python/mako/mako-0.7.3-r1.ebuild
new file mode 100644
index 000000000000..c5f436781470
--- /dev/null
+++ b/dev-python/mako/mako-0.7.3-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_P="Mako-${PV}"
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="http://www.makotemplates.org/ http://pypi.python.org/pypi/Mako"
+SRC_URI="http://www.makotemplates.org/downloads/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~hppa ia64 ppc ~ppc64 s390 sh sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/beaker-1.1[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/test-fix.patch"
+)
+
+python_test() {
+	cp -r -l test "${BUILD_DIR}"/ || die
+
+	if [[ ${EPYTHON} == python3.* ]]; then
+		# Notes:
+		#   -W is not supported by python3.1
+		#   -n causes Python to write into hardlinked files
+		2to3 --no-diffs -w "${BUILD_DIR}"/test || die
+	fi
+
+	cd "${BUILD_DIR}"/test || die
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	rm -rf doc/build
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/mako/mako-0.7.3-r2.ebuild b/dev-python/mako/mako-0.7.3-r2.ebuild
new file mode 100644
index 000000000000..f0ccf6fb51a7
--- /dev/null
+++ b/dev-python/mako/mako-0.7.3-r2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit readme.gentoo versionator distutils-r1
+
+MY_P="Mako-${PV}"
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="http://www.makotemplates.org/ http://pypi.python.org/pypi/Mako"
+SRC_URI="http://www.makotemplates.org/downloads/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~hppa ia64 ppc ~ppc64 ~s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/test-fix.patch"
+)
+
+DOC_CONTENTS="
+${PN} can be enchanced with caching by dev-python/beaker"
+
+python_test() {
+	cp -r -l test "${BUILD_DIR}"/ || die
+
+	if [[ ${EPYTHON} == python3.* ]]; then
+		# Notes:
+		#   -W is not supported by python3.1
+		#   -n causes Python to write into hardlinked files
+		2to3 --no-diffs -w "${BUILD_DIR}"/test || die
+	fi
+
+	cd "${BUILD_DIR}"/test || die
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	rm -rf doc/build
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	for v in ${REPLACING_VERSIONS}; do
+		if ! version_is_at_least 0.7.3-r2 $v; then
+			ewarn "dev-python/beaker is no longer hard dependency of ${P}"
+			ewarn "If you rely on it, you should add beaker to your world"
+			ewarn "file:"
+			ewarn "# emerge --noreplace beaker"
+			break
+		fi
+	done
+}
diff --git a/dev-python/mako/mako-1.0.0.ebuild b/dev-python/mako/mako-1.0.0.ebuild
new file mode 100644
index 000000000000..266b64d5d7a4
--- /dev/null
+++ b/dev-python/mako/mako-1.0.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit readme.gentoo versionator distutils-r1
+
+MY_PN="Mako"
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="http://www.makotemplates.org/ http://pypi.python.org/pypi/Mako"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~hppa ia64 ppc ~ppc64 ~s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOC_CONTENTS="
+${PN} can be enhanced with caching by dev-python/beaker"
+
+python_test() {
+	nosetests "${S}"/test || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	rm -rf doc/build
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	for v in ${REPLACING_VERSIONS}; do
+		if ! version_is_at_least 0.7.3-r2 $v; then
+			ewarn "dev-python/beaker is no longer hard dependency of ${P}"
+			ewarn "If you rely on it, you should add beaker to your world"
+			ewarn "file:"
+			ewarn "# emerge --noreplace beaker"
+			break
+		fi
+	done
+}
diff --git a/dev-python/mako/metadata.xml b/dev-python/mako/metadata.xml
new file mode 100644
index 000000000000..baf06ef2b08a
--- /dev/null
+++ b/dev-python/mako/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>python</herd>
+  <upstream>
+    <remote-id type="pypi">mako</remote-id>
+  </upstream>
+</pkgmetadata>