dev-python/gitdb: Bump to 4.0.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/gitdb/Manifest b/dev-python/gitdb/Manifest
index 2c3413206df5..e76b468ac277 100644
--- a/dev-python/gitdb/Manifest
+++ b/dev-python/gitdb/Manifest
@@ -1 +1,2 @@
 DIST gitdb-4.0.4.tar.gz 392964 BLAKE2B ffbf9d78efc1a12e63ce639018a9c5fde366ae14a85b0ec7ba2866678dbeba2c31ff18cac9b5c4caa2b7e150d3aa5d55434352c38a5155477e053c5ab5eae707 SHA512 a0b2aef8b8b3487c22faeba5d6a60ff2b1a97e3ef075f28bc27140c973242b096463839516ec233065710b7450cb4d885904a7a253e2b518379283edd40cc489
+DIST gitdb-4.0.5.tar.gz 392815 BLAKE2B ab0c557f1233ec6f454769c3d72d982c876cf7b8f67d8b36f9ed8a6a2ee4a04a7a22e1a7453aad0d128436e679940ffea9b2c1e6d433083634b47ffff08b396c SHA512 a3f562928a863121c4051663a0674aa94937527b2fc40a7f392d2913d4d1443bda278e2f7cf362d499389691d24a2d965ab89a6533d42a157db3ab629a377e83
diff --git a/dev-python/gitdb/gitdb-4.0.5.ebuild b/dev-python/gitdb/gitdb-4.0.5.ebuild
new file mode 100644
index 000000000000..16cea188ec73
--- /dev/null
+++ b/dev-python/gitdb/gitdb-4.0.5.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="GitDB is a pure-Python git object database"
+HOMEPAGE="
+	https://github.com/gitpython-developers/gitdb
+	https://pypi.org/project/gitdb/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/smmap-3.0.1[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-vcs/git
+	)"
+
+distutils_enable_tests nose
+
+src_test() {
+	local i
+
+	mkdir "${T}"/repo || die
+	cd "${T}"/repo || die
+
+	for (( i = 0; i < 2500; ++i )); do
+		echo "${i}" > file"${i}" || die
+	done
+
+	git init || die
+	git config user.email "you@example.com" || die
+	git config user.name "Your Name" || die
+	git add -A || die
+	git commit -q -m ".." || die
+	git clone --bare "${T}"/repo "${T}"/repo.git || die
+	cd "${S}" || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	#TRAVIS=1 disables performance tests which rely on the gitdb repo
+	local -x TRAVIS=1
+	local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}