dev-ml/logs: Initial import. Ebuild by me.

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-ml/logs/logs-0.6.2.ebuild b/dev-ml/logs/logs-0.6.2.ebuild
new file mode 100644
index 000000000000..6f93da39eddf
--- /dev/null
+++ b/dev-ml/logs/logs-0.6.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit findlib
+
+DESCRIPTION="Logging infrastructure for OCaml"
+HOMEPAGE="http://erratique.ch/software/logs https://github.com/dbuenzli/logs"
+SRC_URI="http://erratique.ch/software/logs/releases/${P}.tbz"
+
+LICENSE="ISC"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="javascript fmt cli lwt test"
+
+RDEPEND="
+	dev-ml/result:=[ocamlopt]
+	dev-lang/ocaml:=[ocamlopt]
+	javascript? ( dev-ml/js_of_ocaml:= )
+	fmt? ( dev-ml/fmt:= )
+	cli? ( dev-ml/cmdliner:=[ocamlopt] )
+	lwt? ( dev-ml/lwt:= )
+"
+DEPEND="${RDEPEND}
+	dev-ml/opam
+	dev-ml/topkg
+	dev-ml/ocamlbuild
+	dev-ml/findlib
+	test? ( dev-ml/mtime )
+"
+
+src_compile() {
+	ocaml pkg/pkg.ml build \
+		--with-js_of_ocaml $(usex javascript true false) \
+		--with-fmt $(usex fmt true false) \
+		--with-cmdliner $(usex cli true false) \
+		--with-lwt $(usex fmt true false) \
+		--tests $(usex test true false) \
+		|| die
+}
+
+src_test() {
+	ocaml pkg/pkg.ml test || die
+}
+
+src_install() {
+	opam-installer -i \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		${PN}.install || die
+	dodoc CHANGES.md README.md
+}