sci-biology/samri: add 0.5.1

Signed-off-by: Horea Christian <chr@chymera.eu>

2 files changed, 72 insertions, 0 deletions

diff --git a/sci-biology/samri/Manifest b/sci-biology/samri/Manifest
index d683d1d3b..a46860c79 100644
--- a/sci-biology/samri/Manifest
+++ b/sci-biology/samri/Manifest
@@ -1 +1,2 @@
+DIST samri-0.5.1.tar.gz 4121957 BLAKE2B d333067df408f2e60c65b4706f934d436cd8a86bc6eabf8321ecb6f4fe44d88f88deaccb3307d1d275ef1cf3d11b78d530cc56c92944255a00d7ca13173ecac7 SHA512 a702a0ed99d0ed753faeeb41b52b038623c0907a4ff5f573100f019683976bf2c90fc97476fe4c7829c4804d2c13054f0745b631cb9f03e2839e6970f327f179
 DIST samri-0.5.tar.gz 4117149 BLAKE2B 1767d6d07726431e43dad5f843eee04bd5111dde3174905b79b938aa94dbb340ca3f3d6316c6720bf01212b87c895df47c965738dff70ec1debbbd542bb77043 SHA512 94fb981adf78b2062e1beac8433bca34e3db90964f720918603e2b89d617b4dfe9f4bc1591b6953e060553ea0014ebca4db62aa0f5b264feb084bc785a48c367
diff --git a/sci-biology/samri/samri-0.5.1.ebuild b/sci-biology/samri/samri-0.5.1.ebuild
new file mode 100644
index 000000000..a20c63f61
--- /dev/null
+++ b/sci-biology/samri/samri-0.5.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_10 )
+
+inherit distutils-r1 prefix
+
+DESCRIPTION="Small Animal Magnetic Resonance Imaging"
+HOMEPAGE="https://github.com/IBT-FMI/SAMRI"
+SRC_URI="https://github.com/IBT-FMI/SAMRI/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/SAMRI-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+atlases labbookdb"
+REQUIRED_USE="test? ( atlases )"
+
+DEPEND="
+	test? (
+		sci-biology/samri_bidsdata
+		sci-biology/samri_bindata
+		)
+	"
+RDEPEND="
+	dev-python/argh[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-2.0.2[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.13.3[${PYTHON_USEDEP}]
+	dev-python/pandas[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/seaborn[${PYTHON_USEDEP}]
+	dev-python/statsmodels[${PYTHON_USEDEP}]
+	>=media-gfx/blender-2.83.4
+	>=sci-biology/fsl-5.0.9
+	sci-biology/bru2nii
+	atlases? ( sci-biology/mouse-brain-templates )
+	labbookdb? ( sci-libs/labbookdb[${PYTHON_USEDEP}] )
+	sci-libs/nibabel[${PYTHON_USEDEP}]
+	>=sci-libs/nipy-0.4.1[${PYTHON_USEDEP}]
+	>=sci-libs/nipype-1.0.0[${PYTHON_USEDEP}]
+	<sci-libs/pybids-0.10.2[${PYTHON_USEDEP}]
+	sci-libs/scikit-image[${PYTHON_USEDEP}]
+	sci-biology/ants
+	sci-biology/afni
+	sci-biology/nilearn[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc/source dev-python/sphinxcontrib-napoleon
+
+src_prepare() {
+	distutils-r1_src_prepare
+	sed -i -e "s:/usr:@GENTOO_PORTAGE_EPREFIX@/usr:g" `grep -rlI \'/usr/ samri` || die
+	sed -i -e "s:/usr:@GENTOO_PORTAGE_EPREFIX@/usr:g" `grep -rlI /usr/ test_scripts.sh` || die
+	eprefixify $(grep -rl GENTOO_PORTAGE_EPREFIX samri/* test_scripts.sh)
+}
+
+python_test() {
+	distutils_install_for_testing
+	export MPLBACKEND="agg"
+	export PATH=${TEST_DIR}/scripts:$PATH
+	export PYTHONIOENCODING=utf-8
+	./test_scripts.sh || die "Test scripts failed."
+	sed -i -e \
+		"/def test_bru2bids():/i@pytest.mark.skip('Removed in full test suite, as this is already tested in `test_scripts.sh`')" \
+		samri/pipelines/tests/test_repos.py || die
+	epytest -k "not longtime"
+}