blob: 79c11acbea51f7c4c34c93de3dd394ba95054398 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
KFMIN=5.99.0
QTMIN=5.15.5
VIRTUALX_REQUIRED="test"
inherit ecm flag-o-matic gear.kde.org
DESCRIPTION="Multi-document editor with network transparency, Plasma integration and more"
HOMEPAGE="https://kate-editor.org/ https://apps.kde.org/kate/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE=""
DEPEND="
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
~kde-apps/kate-lib-${PV}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
"
RDEPEND="${DEPEND}
~kde-apps/kate-addons-${PV}:5
"
src_prepare() {
ecm_src_prepare
# these tests are run in kde-apps/kate-lib
cmake_run_in apps/lib cmake_comment_add_subdirectory autotests
# delete colliding kwrite translations
rm -f po/*/*.po || die # installed by kde-apps/kate-lib
rm -rf po/*/docs/kwrite || die
}
src_configure() {
local mycmakeargs=(
-DBUILD_addons=FALSE
-DBUILD_kwrite=FALSE
)
# provided by kde-apps/kate-lib
append-libs -lkateprivate
ecm_src_configure
}
src_install() {
ecm_src_install
# provided by kde-apps/kate-lib
rm -v "${ED}"/usr/$(get_libdir)/libkateprivate.so.* || die
}
|
GitWeb
