dbus-glib-0.86 cross compilation fix

Signed-off-by: Maksim 'max_posedon' Melnikau <maxposedon@gmail.com>

1 files changed, 110 insertions, 0 deletions

diff --git a/dev-libs/dbus-glib/dbus-glib-0.86.ebuild b/dev-libs/dbus-glib/dbus-glib-0.86.ebuild
new file mode 100644
index 0000000..a12e95b
--- /dev/null
+++ b/dev-libs/dbus-glib/dbus-glib-0.86.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/dbus-glib-0.86.ebuild,v 1.2 2010/04/07 04:22:40 darkside Exp $
+
+EAPI="2"
+
+inherit eutils bash-completion
+
+DESCRIPTION="D-Bus bindings for glib"
+HOMEPAGE="http://dbus.freedesktop.org/"
+SRC_URI="http://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 AFL-2.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="bash-completion debug doc test"
+
+RDEPEND=">=sys-apps/dbus-1.1
+	>=dev-libs/glib-2.10
+	>=dev-libs/expat-1.95.8"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/gettext
+	doc? (
+		app-doc/doxygen
+		app-text/xmlto
+		>=dev-util/gtk-doc-1.4 )"
+
+# out of sources build directory
+BD=${WORKDIR}/${P}-build
+# out of sources build dir for make check
+TBD=${WORKDIR}/${P}-tests-build
+
+BASHCOMPLETION_NAME="dbus"
+
+src_prepare() {
+	# We need a dbus-binding-tool installed on the host for cross-compilation.
+	# So check if we have it in the path and can call it right at the beginning...
+	if tc-is-cross-compiler ; then
+		dbus-binding-tool --version >/dev/null 2>&1
+		[[ "$?" != "0" ]] && die "Cross-compilation requires a dbus-binding-tool on the host. Please emerge dbus-glib to your host!"
+	fi
+
+	# description ?
+	epatch "${FILESDIR}"/${PN}-introspection.patch
+}
+
+src_configure() {
+	local my_conf
+
+	my_conf="--localstatedir=/var
+		$(use_enable bash-completion)
+		$(use_enable debug verbose-mode)
+		$(use_enable debug asserts)
+		$(use_enable doc doxygen-docs)
+		$(use_enable doc gtk-doc)"
+
+	# For cross-compilation we need the host dbus-binding-tool
+	if tc-is-cross-compiler ; then
+		my_conf="${myconf} \
+				--with-dbus-binding-tool=dbus-binding-tool"
+	fi
+
+	mkdir "${BD}"
+	cd "${BD}"
+	einfo "Running configure in ${BD}"
+	ECONF_SOURCE="${S}" econf ${my_conf}
+
+	if use test; then
+		mkdir "${TBD}"
+		cd "${TBD}"
+		einfo "Running configure in ${TBD}"
+		ECONF_SOURCE="${S}" econf \
+			${my_conf} \
+			$(use_enable test checks) \
+			$(use_enable test tests) \
+			$(use_enable test asserts) \
+			$(use_with test test-socket-dir "${T}"/dbus-test-socket)
+	fi
+}
+
+src_compile() {
+	cd "${BD}"
+	einfo "Running make in ${BD}"
+	emake || die "make failed"
+
+	if use test; then
+		cd "${TBD}"
+		einfo "Running make in ${TBD}"
+		emake || die "make failed"
+	fi
+}
+
+src_test() {
+	cd "${TBD}"
+	emake check || die "make check failed"
+}
+
+src_install() {
+	dodoc AUTHORS ChangeLog HACKING NEWS README || die "dodoc failed."
+
+	cd "${BD}"
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	# FIXME: We need --with-bash-completion-dir
+	if use bash-completion ; then
+		dobashcompletion "${D}"/etc/bash_completion.d/dbus-bash-completion.sh
+		rm -rf "${D}"/etc/bash_completion.d || die "rm failed"
+	fi
+}