1 files changed, 68 insertions, 0 deletions
diff --git a/app-admin/mon/mon-1.2.0.ebuild b/app-admin/mon/mon-1.2.0.ebuild
new file mode 100644
index 0000000..d5579e6
--- /dev/null
+++ b/app-admin/mon/mon-1.2.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+inherit toolchain-funcs eutils multilib
+
+DESCRIPTION="highly configurable service monitoring daemon"
+HOMEPAGE="http://www.kernel.org/software/mon/"
+SRC_URI="mirror://kernel/software/admin/mon/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc x86"
+IUSE="ldap mysql pam"
+
+DEPEND=">=dev-perl/Mon-0.11
+	>=virtual/perl-Time-HiRes-1.20
+	dev-perl/Convert-BER
+	dev-perl/Filesys-DiskSpace
+	dev-perl/Net-Telnet
+	ldap? ( dev-perl/perl-ldap )
+	dev-perl/Expect
+	dev-perl/Net-DNS
+	mysql? ( dev-perl/DBD-mysql )
+	pam? ( dev-perl/Authen-PAM )
+	>=dev-perl/Period-1.20-r2"
+
+src_unpack() {
+	unpack "${A}"
+	cd "${S}"
+	epatch "${FILESDIR}/${P}-sendmail.patch"
+	epatch "${FILESDIR}/${P}-syslog.patch"
+}
+
+src_compile() {
+	cd "${S}"/mon.d
+	make CC="$(tc-getCC) ${CFLAGS}" || die
+}
+
+src_install() {
+	dosbin mon clients/mon*
+
+	insinto /usr/$(get_libdir)/mon/utils
+	doins utils/*
+
+	exeinto /usr/$(get_libdir)/mon/alert.d
+	doexe alert.d/*
+
+	exeinto /usr/$(get_libdir)/mon/mon.d
+	doexe mon.d/*.monitor
+
+	insopts -g uucp -m 02555
+	doins mon.d/*.wrap
+
+	dodir /var/log/mon.d
+	dodir /var/lib/mon.d
+
+	doman doc/*.{1,8}
+	dodoc CHANGES doc/CHANGES* CREDITS \
+		KNOWN-PROBLEMS README TODO VERSION \
+		doc/README* doc/*.txt
+	docinto etc; dodoc etc/*
+	newdoc "${FILESDIR}"/mon.cf mon.cf.sample
+
+	newinitd "${FILESDIR}"/mon.init mon
+	insinto /etc/mon
+	newins "${FILESDIR}"/mon.cf mon.cf.sample
+}