x11-misc/xnee/xnee-3.02.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xnee/xnee-3.02.ebuild,v 1.2 2008/02/03 18:12:53 drac Exp $

inherit eutils

DESCRIPTION="Program suite to record, replay and distribute user actions."
HOMEPAGE="http://www.sandklef.com/xnee"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gnome gtk xosd"

RDEPEND="x11-libs/libX11
	x11-libs/libXtst
	gtk? ( >=x11-libs/gtk+-2 )
	gnome? ( gnome-base/gconf
		gnome-base/gnome-panel )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	gtk? ( sys-devel/gettext media-gfx/imagemagick )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-destdir.patch
}

src_compile() {
	local myconf

	if use xosd; then
		myconf="--enable-xosd --enable-verbose --enable-buffer_verbose"
	else
		myconf="--disable-xosd --disable-verbose --disable-buffer_verbose"
	fi

	econf ${myconf} --enable-cli --enable-lib \
		$(use_enable gnome gnome-applet) \
		$(use_enable gtk gui)

	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc AUTHORS BUGS ChangeLog FAQ NEWS README TODO

	if use gtk; then
		doicon pixmap/${PN}.png
		make_desktop_entry gnee Gnee ${PN} "Utility;GTK"
	fi
}