x11-libs/rep-gtk/rep-gtk-0.18-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/rep-gtk/rep-gtk-0.18-r2.ebuild,v 1.6 2005/09/02 19:28:24 hansmi Exp $

inherit eutils toolchain-funcs multilib

IUSE="gnome"

DESCRIPTION="A GTK+/libglade/GNOME language binding for the librep Lisp environment"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
HOMEPAGE="http://rep-gtk.sourceforge.net/"
SLOT="gtk-2.0"
LICENSE="GPL-2"
KEYWORDS="alpha amd64 ia64 ppc sparc x86"

DEPEND="virtual/libc
	>=dev-libs/librep-0.13
	>=dev-util/pkgconfig-0.12.0
	>=gnome-base/libglade-2.0.0
	>=sys-devel/automake-1.6.1-r5
	>=x11-libs/gtk+-2.0.3
	gnome? (
		>=gnome-base/libbonobo-2.0.0
		>=gnome-base/libbonoboui-2.0.0
		>=gnome-base/libgnome-2.0.0
		>=gnome-base/libgnomeui-2.0.0
		>=gnome-base/libgnomecanvas-2.0.0
	)"

src_unpack() {
	unpack ${A}
	cd ${S} || die

	# Fix for bug 45646 to sync up rep-gtk headers with gtk+
	if has_version '>=x11-libs/gtk+-2.4'; then
		epatch ${FILESDIR}/rep-gtk-0.18-gtk24.patch
	fi

	# Remove reference to gtk internal functions.  These functions are no
	# longer available in recent versions of gtk, and sawfish doesn't use
	# them anyway.  Bug 48439, patch from fn_x
	epatch ${FILESDIR}/rep-gtk-0.18-gtk26.patch
}

src_compile() {
	CC=$(tc-getCC) econf \
		--with-libglade \
		--with-gdk-pixbuf \
		--libdir=/usr/$(get_libdir) \
		$(use_with gnome) || die
	emake host_type=${CHOST} || die
}

src_install() {
	make install \
		host_type=${CHOST} \
		installdir=${D}/usr/$(get_libdir)/rep/${CHOST} || die

	cd ${S}
	dodoc AUTHORS BUGS COPYING ChangeLog HACKING \
		NEWS README* TODO
}