www-apps/xrms/xrms-1.99.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/xrms/xrms-1.99.2.ebuild,v 1.4 2008/02/22 15:58:41 hollow Exp $

inherit webapp depend.php eutils

MY_DATE="2006-07-25"

DESCRIPTION="Advanced Customer Relationship Management (CRM) and Sales Force Automation (SFA) suite"
HOMEPAGE="http://xrms.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_DATE}-v${PV}-.tar.gz"

LICENSE="OSL-2.0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=""
RDEPEND="dev-php/PEAR-PEAR"

need_httpd_cgi
need_php_httpd

S="${WORKDIR}"/${PN}

pkg_setup() {
	webapp_pkg_setup
	require_php_with_use mysql
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	ecvs_clean
}

src_install () {
	webapp_src_preinst

	dodoc CHANGELOG README install/INSTALL
	rm -f CHANGELOG README install/INSTALL LICENSE

	insinto "${MY_HOSTROOTDIR}"/${PF}/include
	doins -r include/
	rm -rf include/

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	webapp_serverowned "${MY_HTDOCSDIR}"/{export,storage,tmp}

	webapp_configfile "${MY_HTDOCSDIR}"/include-locations.inc
	webapp_configfile "${MY_HOSTROOTDIR}"/${PF}/include/vars.php
	webapp_configfile "${MY_HOSTROOTDIR}"/${PF}/include/plugin-cfg.php
	webapp_configfile "${MY_HOSTROOTDIR}"/${PF}/include/classes/SMTPs/SMTPs.ini.php

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt
	webapp_hook_script "${FILESDIR}"/reconfig

	webapp_src_install
}