sys-fs/progsreiserfs/progsreiserfs-0.3.1_rc8.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/progsreiserfs/progsreiserfs-0.3.1_rc8.ebuild,v 1.4 2005/01/11 18:44:56 vapier Exp $

inherit libtool flag-o-matic

MY_P=${PN}-${PV/_/-}
DESCRIPTION="library for accessing and manipulating reiserfs partitions"
HOMEPAGE="http://reiserfs.linux.kiev.ua/"
SRC_URI="http://reiserfs.linux.kiev.ua/snapshots/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="nls debug"

RDEPEND=""
DEPEND="nls? ( sys-devel/gettext )"

S="${WORKDIR}/${MY_P}"

progsreiserfs_warning() {
	ewarn "progsreiserfs has been proven dangerous in the past, generating bad"
	ewarn "partitions and destroying data on resize/cpfs operations."
}

src_compile() {
	elibtoolize
	filter-lfs-flags
	econf \
		--disable-Werror \
		$(use_enable nls) \
		$(use_enable debug) \
		|| die "Configure failed"
	emake || die "Make failed"
	progsreiserfs_warning
}

src_install() {
	make install DESTDIR="${D}" || die "Install failed"
	# Make sure users only use the official namesys binaries
	rm -r "${D}"/usr/{sbin,share/man} || die "cant punt the cruft"

	dodoc AUTHORS BUGS ChangeLog NEWS README THANKS TODO
	docinto demos
	dodoc demos/*.c
	progsreiserfs_warning
}

pkg_postinst() {
	progsreiserfs_warning
}
pkg_preinst() {
	progsreiserfs_warning
}