blob: e8ffbc6c3ac69f537c88a9a99cc4bc88b1251b1e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/aufs3/aufs3-3_p20110815.ebuild,v 1.1 2011/08/28 09:48:57 jlec Exp $
EAPI=4
inherit linux-mod multilib toolchain-funcs
AUFS_VERSION="${PV%%_p*}"
DESCRIPTION="An entirely re-designed and re-implemented Unionfs"
HOMEPAGE="http://aufs.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~jlec/distfiles/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc fuse pax_kernel hfs inotify kernel-patch nfs ramfs"
DEPEND="dev-vcs/git"
RDEPEND="
!sys-fs/aufs
!sys-fs/aufs2"
S="${WORKDIR}"/${PN}-standalone
MODULE_NAMES="aufs(misc:${S})"
pkg_setup() {
CONFIG_CHECK="${CONFIG_CHECK} ~EXPERIMENTAL"
use inotify && CONFIG_CHECK="${CONFIG_CHECK} ~FSNOTIFY"
use nfs && CONFIG_CHECK="${CONFIG_CHECK} EXPORTFS"
use fuse && CONFIG_CHECK="${CONFIG_CHECK} ~FUSE_FS"
use hfs && CONFIG_CHECK="${CONFIG_CHECK} ~HFSPLUS_FS"
# this is needed so merging a binpkg ${PN} is possible w/out a kernel unpacked on the system
[ -n "$PKG_SETUP_HAS_BEEN_RAN" ] && return
get_version
kernel_is lt 3 0 0 && die "kernel too old, Please use sys-fs/aufs2"
kernel_is gt 3 0 99 && die "kernel too new"
linux-mod_pkg_setup
if ! ( patch -p1 --dry-run --force -R -d ${KV_DIR} < "${FILESDIR}"/${PN}-standalone-${KV_MINOR}.patch >/dev/null && \
patch -p1 --dry-run --force -R -d ${KV_DIR} < "${FILESDIR}"/${PN}-base-${KV_MINOR}.patch >/dev/null ); then
if use kernel-patch; then
cd ${KV_DIR}
ewarn "Patching your kernel..."
patch --no-backup-if-mismatch --force -p1 -R -d ${KV_DIR} < "${FILESDIR}"/${PN}-standalone-${KV_MINOR}.patch >/dev/null
patch --no-backup-if-mismatch --force -p1 -R -d ${KV_DIR} < "${FILESDIR}"/${PN}-base-${KV_MINOR}.patch >/dev/null
epatch "${FILESDIR}"/${PN}-{base,standalone}-${KV_MINOR}.patch
ewarn "You need to compile your kernel with the applied patch"
ewarn "to be able to load and use the aufs kernel module"
else
eerror "You need to apply a patch to your kernel to compile and run the ${PN} module"
eerror "Either enable the kernel-patch useflag to do it with this ebuild"
eerror "or apply ${FILESDIR}/${PN}-base-${KV_MINOR}.patch and"
eerror "${FILESDIR}/${PN}-standalone-${KV_MINOR}.patch by hand"
die "missing kernel patch, please apply it first"
fi
fi
export PKG_SETUP_HAS_BEEN_RAN=1
}
set_config() {
for option in $*; do
grep -q "^CONFIG_AUFS_${option} =" config.mk || die "${option} is not a valid config option"
sed "/^CONFIG_AUFS_${option}/s:=:= y:g" -i config.mk || die
done
}
src_prepare() {
# local branch=origin/${PN}-${KV_MINOR}
local branch=origin/${PN}.0
git checkout -q $branch || die
# All config options to off
sed "s:= y:=:g" -i config.mk || die
set_config RDU BRANCH_MAX_127 SBILIST
use debug && set_config DEBUG
use fuse && set_config BR_FUSE POLL
use hfs && set_config BR_HFSPLUS
use inotify && set_config HNOTIFY HFSNOTIFY
use nfs && set_config EXPORT
use nfs && use amd64 && set_config INO_T_64
use ramfs && set_config BR_RAMFS
use pax_kernel && epatch "${FILESDIR}"/pax.patch
sed -i "s:aufs.ko usr/include/linux/aufs_type.h:aufs.ko:g" Makefile || die
sed -i "s:__user::g" include/linux/aufs_type.h || die
cd "${WORKDIR}"/${PN/3}-util
git checkout -q origin/${PN}.0
sed -i "/LDFLAGS += -static -s/d" Makefile || die
sed -i -e "s:m 644 -s:m 644:g" -e "s:/usr/lib:/usr/$(get_libdir):g" libau/Makefile || die
}
src_compile() {
local ARCH=x86
emake CC=$(tc-getCC) CONFIG_AUFS_FS=m KDIR=${KV_DIR}
cd "${WORKDIR}"/${PN/3}-util
emake CC=$(tc-getCC) AR=$(tc-getAR) KDIR=${KV_DIR} C_INCLUDE_PATH="${S}"/include
}
src_install() {
linux-mod_src_install
insinto /usr/share/doc/${PF}
use doc && doins -r Documentation
dodoc README
cd "${WORKDIR}"/${PN/3}-util
emake DESTDIR="${D}" KDIR=${KV_DIR} install
newdoc README README-utils
}
|
GitWeb