sys-apps/proot/proot-3.2.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/proot/proot-3.2.1-r1.ebuild,v 1.1 2013/12/23 16:18:23 pinkbyte Exp $

EAPI=5
MY_PN="PRoot"

inherit eutils pax-utils toolchain-funcs

DESCRIPTION="User-space implementation of chroot, mount --bind, and binfmt_misc"
HOMEPAGE="http://proot.me"
SRC_URI="https://github.com/cedric-vincent/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND="sys-libs/talloc"
DEPEND="${RDEPEND}
	test? ( dev-util/valgrind )"

# Breaks sandbox
RESTRICT="test"

S="${WORKDIR}/${MY_PN}-${PV}"

src_prepare() {
	epatch  "${FILESDIR}/${P}-makefile.patch" \
		"${FILESDIR}/${PN}-2.3.1-lib-paths-fix.patch"
	epatch_user
}

src_compile() {
	emake -C src V=1 \
		CC="$(tc-getCC)" \
		CHECK_VERSION="true"
}

src_install() {
	# Workaround for bug #493416
	pax-mark -Emp src/proot

	dobin src/proot
	doman doc/proot.1
	dodoc doc/*.txt doc/articles/*
}

src_test() {
	emake -C tests -j1 CC="$(tc-getCC)"
}