sci-mathematics/spin/spin-5.2.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/spin/spin-5.2.4.ebuild,v 1.1 2010/04/11 12:50:07 phajdan.jr Exp $

EAPI="2"

inherit eutils versionator

MY_PV=$(replace_all_version_separators '')
MY_P="${PN}${MY_PV}"

DESCRIPTION="Tool for formal verification of distributed software systems."
HOMEPAGE="http://spinroot.com/"
SRC_URI="http://spinroot.com/spin/Src/${MY_P}.tar.gz
	http://spinroot.com/spin/Src/xspin523.tcl"

LICENSE="|| ( spin-commercial spin-educational )"
SLOT="0"
KEYWORDS="~x86"
IUSE="graphviz tk"

DEPEND="sys-devel/bison"
RDEPEND="sys-devel/gcc
	sys-process/time
	tk? (
		dev-lang/tk
		graphviz? ( media-gfx/graphviz )
	)"

S="${WORKDIR}/Spin/Src${PV}"

src_unpack() {
	unpack "${MY_P}.tar.gz"
	cp "${DISTDIR}/xspin523.tcl" "${S}" || die "cp failed"
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-makefile.patch"
	epatch "${FILESDIR}/${PN}-xspin.patch"
}

src_compile() {
	emake -j1 || die "emake failed"
}

src_install() {
	dobin spin || die "dobin failed"
	doman ../Man/spin.1 || die "doman failed"
	dodoc ../Doc/* || die "dodoc failed"
	if use tk; then
		newbin xspin523.tcl xspin || die "newbin failed"
		make_desktop_entry xspin XSpin
	fi
}