sci-astronomy/cpl/cpl-5.2.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/cpl/cpl-5.2.0.ebuild,v 1.1 2010/05/26 19:02:45 bicatali Exp $

EAPI=2
JAVA_PKG_OPT_USE=gasgano
inherit java-pkg-opt-2

DESCRIPTION="ESO common pipeline library for astronomical data reduction"
HOMEPAGE="http://www.eso.org/sci/data-processing/software/cpl/"
SRC_URI="ftp://ftp.eso.org/pub/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="doc gasgano"

RDEPEND=">=sci-libs/cfitsio-3.09
	sci-astronomy/wcslib
	sci-libs/fftw:3.0
	gasgano? ( sci-astronomy/gasgano )"
DEPEND="${RDEPEND}
	sys-devel/libtool
	doc? ( app-doc/doxygen )
	gasgano? ( >=virtual/jdk-1.5 )"

src_configure() {
	local myconf="--without-gasgano"
	use gasgano && \
		myconf="--with-gasgano=/usr
				--with-gasgano-classpath=/usr/share/gasgano/lib"
	econf \
		--with-cfitsio="/usr" \
		--with-wcs="/usr" \
		--with-fftw="/usr" \
		${myconf}
}

src_compile() {
	emake || die "emake failed"
	if use doc; then
		doxygen Doxyfile || die
	fi
}
src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README AUTHORS NEWS TODO BUGS ChangeLog
	if use doc; then
		insinto /usr/share/doc/${PF}
		doins -r html || die
	fi
}