net-news/liferea/liferea-1.9.6_p20121021.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/liferea-1.9.6_p20121021.ebuild,v 1.1 2012/10/21 18:27:56 vostorga Exp $

EAPI=4

GCONF_DEBUG=no

inherit eutils gnome2 pax-utils

MY_P=${PN}
S=${WORKDIR}/${MY_P}

DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo feeds"
HOMEPAGE="http://liferea.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~vostorga/distfiles/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="ayatana libnotify"

RDEPEND=">=x11-libs/gtk+-2.91.4:3
	>=dev-libs/glib-2.26.0:2
	>=x11-libs/pango-1.4.0
	>=gnome-base/gconf-1.1.9:2
	>=dev-libs/libxml2-2.6.27:2
	>=dev-libs/libxslt-1.1.19
	>=dev-db/sqlite-3.7.0:3
	>=net-libs/libsoup-2.28.2:2.4
	dev-libs/libunique:3
	>=net-libs/webkit-gtk-1.6.1:3
	dev-libs/json-glib
	ayatana? ( dev-libs/libindicate )
	libnotify? ( >=x11-libs/libnotify-0.3.2 )
	>=dev-libs/libpeas-1.0.0[gtk]
	gnome-base/gsettings-desktop-schemas"
DEPEND="${RDEPEND}
	dev-util/intltool
	virtual/pkgconfig"

DOCS="AUTHORS ChangeLog README"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	G2CONF="${G2CONF}
		--enable-sm
		--disable-schemas-install
		$(use_enable ayatana libindicate)
		$(use_enable libnotify)"
}

src_prepare() {
	./autogen.sh || die
	gnome2_src_prepare
}

src_install() {
	gnome2_src_install
	# bug #338213
	# Uses webkit's JIT. Needs mmap('rwx') to generate code in runtime.
	# MPROTECT policy violation. Will sit here until webkit will
	# get optional JIT.
	pax-mark m "${D}"/usr/bin/liferea

	einfo "If you want to enhance funcitonality of this package"
	einfo "You should consider installing these packages:"
	einfo "    dev-libs/dbus-glib"
	einfo "    net-misc/networkmanager"
}