blob: e2ecc4c1e5847b00b6f828b41f357aa669236c23 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/rdesktop-1.6.0-r4.ebuild,v 1.4 2010/12/29 14:26:45 jer Exp $
EAPI=2
inherit autotools eutils
MY_PV=${PV/_/-}
DESCRIPTION="A Remote Desktop Protocol Client"
HOMEPAGE="http://rdesktop.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.tar.gz
rdpusb? ( mirror://gentoo/${P}-rdpusb.patch.bz2 )"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 hppa ~ia64 ~mips ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="alsa ao debug ipv6 libsamplerate oss pcsc-lite rdpusb"
S=${WORKDIR}/${PN}-${MY_PV}
RDEPEND=">=dev-libs/openssl-0.9.6b
x11-libs/libX11
x11-libs/libXext
x11-libs/libXau
x11-libs/libXdmcp
alsa? ( media-libs/alsa-lib )
ao? ( >=media-libs/libao-0.8.6 )
libsamplerate? ( media-libs/libsamplerate )
pcsc-lite? ( sys-apps/pcsc-lite )"
DEPEND="${RDEPEND}
x11-libs/libXt"
src_prepare() {
# Prevent automatic stripping
local strip="$(echo '$(STRIP) $(DESTDIR)$(bindir)/rdesktop')"
sed -i -e "s:${strip}::" Makefile.in \
|| die "sed failed in Makefile.in"
# Automagic dependency on libsamplerate
epatch "${FILESDIR}"/${P}-sound_configure.patch
# Fix --enable-smartcard logic
epatch "${FILESDIR}"/${P}-smartcard_configure.patch
# USB redirection support from virtualbox
use rdpusb && epatch "${WORKDIR}"/${P}-rdpusb.patch
# bug #349813
epatch "${FILESDIR}"/${P}+pcsc-lite-1.6.6.patch
eautoreconf
}
src_configure() {
if use ao; then
sound_conf=$(use_with ao sound libao)
else if use alsa; then
sound_conf=$(use_with alsa sound alsa)
else
sound_conf=$(use_with oss sound oss)
fi
fi
econf \
--with-openssl=/usr \
$(use_with debug) \
$(use_with ipv6) \
$(use_with libsamplerate) \
$(use_enable pcsc-lite smartcard) \
${sound_conf} \
|| die "configuration failed"
}
src_install() {
emake DESTDIR="${D}" install || die "installation failed"
dodoc doc/HACKING doc/TODO doc/keymapping.txt
# For #180313 - applies to versions >= 1.5.0
# Fixes sf.net bug
# http://sourceforge.net/tracker/index.php?func=detail&aid=1725634&group_id=24366&atid=381349
# check for next version to see if this needs to be removed
insinto /usr/share/rdesktop/keymaps
newins "${FILESDIR}/rdesktop-keymap-additional" additional
newins "${FILESDIR}/rdesktop-keymap-cs" cs
newins "${FILESDIR}/rdesktop-keymap-sk" sk
}
|
GitWeb