net-misc/nxclient/nxclient-1.5.0-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/nxclient/nxclient-1.5.0-r2.ebuild,v 1.1 2006/01/11 23:52:20 agriffis Exp $

inherit rpm

DESCRIPTION="NXClient is a X11/VNC/NXServer client especially tuned for using remote desktops over low-bandwidth links such as the Internet"
HOMEPAGE="http://www.nomachine.com"

IUSE=""
LICENSE="as-is"
SLOT="0"
KEYWORDS="-alpha ~amd64 -mips -ppc -sparc ~x86"
RESTRICT="nostrip"

SRC_URI="http://web04.nomachine.com/download/1.5.0/client/$P-135.i386.rpm"

DEPEND="
	=net-misc/nxssh-1.5*
	net-analyzer/gnu-netcat
	amd64? (
		>=app-emulation/emul-linux-x86-baselibs-2.1.4
	)
	x86? (
		media-libs/jpeg
		sys-libs/glibc
		sys-libs/zlib
		virtual/x11
		dev-libs/expat
		media-libs/fontconfig
		media-libs/freetype
		media-libs/jpeg
		x11-libs/qt
	)"

S=${WORKDIR}

src_install() {
	# rpm has usr/NX/; tarball has only NX/
	if [[ ! -d usr ]]; then
		mkdir usr
		mv NX usr || die
	fi

	cp -dPR usr ${D}

	# All of the libraries delivered by nxclient are available in our deps.
	# Additionally a couple of the binaries are better installed as deps.
	# Remove those now...

	# delivered by net-misc/nxcomp
	rm -f ${D}/usr/NX/lib/libXcomp.so*

	# delivered by net-misc/nx-x11 (at some point)
	rm -f ${D}/usr/NX/bin/nxesd

	# delivered by net-misc/nxssh
	rm -f ${D}/usr/NX/bin/nxssh

	# delivered by other deps (emul-linux-x86-baselibs on amd64)
	rm -f ${D}/usr/NX/lib/lib{crypto,jpeg,png,z}*

	# make sure there are no libs left (this is to catch problems when this
	# package is updated)
	rmdir ${D}/usr/NX/lib || die "leftover libraries in ${D}/usr/NX/lib"

	# FIXME: Of the options in the applnk directory, the desktop files in the
	# "network" directory seem to make the most sense.  I have no idea if this
	# works for KDE or just for Gnome.
	declare applnk=/usr/NX/share/applnk apps=/usr/share/applications
	if [[ -d ${D}${applnk} ]]; then
		dodir ${apps}
		mv ${D}${applnk}/network/*.desktop ${D}${apps}
		rm ${D}${apps}/nxclient-help.desktop
		rm -rf ${D}${applnk}
	fi

	# Install env.d snippet to add /usr/NX/bin to the PATH
	insinto /etc/env.d
	doins ${FILESDIR}/1.5.0/50nxclient
}